इस पेज का अनुवाद Cloud Translation API से किया गया है.

Gradle से जुड़ी सलाह और रेसिपी

Gradle और Gradle के लिए Android प्लग इन, आपके Android ऐप्लिकेशन या लाइब्रेरी को कंपाइल करने, बनाने, और पैकेज करने का आसान तरीका उपलब्ध कराते हैं. इस पेज पर कुछ काम की सलाह और कॉन्फ़िगरेशन दिए गए हैं. इनकी मदद से, हर बिल्ड का ज़्यादा से ज़्यादा फ़ायदा लिया जा सकता है. अगर आपको अपने बिल्ड को तेज़ बनाने के तरीकों के बारे में जानना है, तो बिल्ड की स्पीड ऑप्टिमाइज़ करना लेख पढ़ें.

अगर आपने पहले कभी Gradle का इस्तेमाल नहीं किया है, तो अपना बिल्ड कॉन्फ़िगर करना लेख पढ़कर, इसके बारे में बुनियादी जानकारी पाएं. इस पेज पर इस्तेमाल की गई प्रॉपर्टी के बारे में ज़्यादा जानने के लिए, Android प्लग इन के डीएसएल रेफ़रंस दस्तावेज़ की जांच भी की जा सकती है.

प्रोजेक्ट और सोर्स मैनेज करना

यहां आपके प्रोजेक्ट के मॉड्यूल और उनके सोर्स को मैनेज करने के लिए कुछ कॉन्फ़िगरेशन दिए गए हैं. प्रोजेक्ट और मॉड्यूल बनाने और उन्हें मैनेज करने के बारे में ज़्यादा जानने के लिए, प्रोजेक्ट की खास जानकारी पढ़ें.

सोर्स सेट के डिफ़ॉल्ट कॉन्फ़िगरेशन बदलना

मॉड्यूल-लेवल की build.gradle फ़ाइल में sourceSets ब्लॉक का इस्तेमाल करके, यह बदला जा सकता है कि Gradle, सोर्स सेट के हर कॉम्पोनेंट के लिए फ़ाइलें कहां से इकट्ठा करे.

Groovy

android {
  ...
  sourceSets {
    // Encapsulates configurations for the main source set.
    main {
      // Changes the directory for Java sources. The default directory is
      // 'src/main/java'.
      java.srcDirs = ['other/java']

      // When you list multiple directories, Gradle uses all of them to collect
      // sources. You should avoid specifying a directory which is a parent to one
      // or more other directories you specify.
      res.srcDirs = ['other/res1', 'other/res2']

      // For each source set, you can specify only one Android manifest.
      // The following points Gradle to a different manifest for this source set.
      manifest.srcFile 'other/AndroidManifest.xml'
      ...
    }

    // Create additional blocks to configure other source sets.
    androidTest {

      // If all the files for a source set are located under a single root
      // directory, you can specify that directory using the setRoot property.
      // When gathering sources for the source set, Gradle looks only in locations
      // relative to the root directory you specify. For example, after applying
      // the configuration below for the androidTest source set, Gradle looks for
      // Java sources only in the src/tests/java/ directory.
      setRoot 'src/tests'
      ...
    }
  }
}
...

Kotlin

android {
  ...
  sourceSets {
    // Encapsulates configurations for the main source set.
    getByName("main") {
      // Changes the directory for Java sources. The default directory is
      // 'src/main/java'.
      java.setSrcDirs("other/java")

      // When you list multiple directories, Gradle uses all of them to collect
      // sources. You should avoid specifying a directory which is a parent to one
      // or more other directories you specify.
      res.setSrcDirs("other/res1", "other/res2")

      // For each source set, you can specify only one Android manifest.
      // The following points Gradle to a different manifest for this source set.
      manifest.srcFile("other/AndroidManifest.xml")
      ...
    }

    // Create additional blocks to configure other source sets.
    androidTest {

      // If all the files for a source set are located under a single root
      // directory, you can specify that directory using the setRoot property.
      // When gathering sources for the source set, Gradle looks only in locations
      // relative to the root directory you specify. For example, after applying
      // the configuration below for the androidTest source set, Gradle looks for
      // Java sources only in the src/tests/java/ directory.
      setRoot("src/tests")
      ...
    }
  }
}
...

लाइब्रेरी और डिपेंडेंसी मैनेज करना

Gradle, डिपेंडेंसी मैनेज करने के लिए एक बेहतरीन तरीका उपलब्ध कराता है. भले ही, वे रिमोट लाइब्रेरी हों या स्थानीय लाइब्रेरी मॉड्यूल.

डिपेंडेंसी कॉन्फ़िगरेशन की मदद से, खास बिल्ड को टारगेट करना

अगर आपको सिर्फ़ किसी खास बिल्ड वैरिएंट सोर्स सेट या टेस्टिंग सोर्स सेट के लिए डिपेंडेंसी चाहिए, तो डिपेंडेंसी कॉन्फ़िगरेशन के नाम को कैपिटल लेटर में लिखें और उसके आगे बिल्ड वैरिएंट या टेस्टिंग सोर्स सेट का नाम जोड़ें.

Groovy

android {...}

// Creates Gradle dependency configurations to use in the dependencies block.
configurations {
  // For variants that combine a product flavor and build type, you need to
  // intitialize a placeholder for its dependency configuration.
  freeDebugRuntimeOnly{}
  ...
}

dependencies {
    // Adds an implementation dependency only to the "free" product flavor.
    freeImplementation 'com.google.firebase:firebase-ads:21.5.1'
    // Adds a runtimeOnly dependency only to the "freeDebug" build variant.
    freeDebugRuntimeOnly fileTree(dir: 'libs', include: ['*.jar'])
    // Adds a remote binary dependency only for local tests.
    testImplementation 'junit:junit:4.12'
    // Adds a remote binary dependency only for the instrumented test APK.
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.6.1'
}

Kotlin

android {...}

dependencies {
    // Use ""() notation for custom flavors and build types
    // Adds an implementation dependency only to the "free" product flavor.
    "freeImplementation"("com.google.firebase:firebase-ads:21.5.1")
    // Adds a runtimeOnly dependency only to the "freeDebug" build variant.
    "freeDebugRuntimeOnly"(fileTree("dir" to "libs", "include" to "*.jar"))
    // Adds a remote binary dependency only for local tests.
    testImplementation("junit:junit:4.12")
    // Adds a remote binary dependency only for the instrumented test APK.
    androidTestImplementation("com.android.support.test.espresso:espresso-core:3.6.1")
}

अपने ऐप्लिकेशन के अलग-अलग वर्शन बनाना

Gradle और Android प्लग इन की मदद से, बिल्ड वैरिएंट कॉन्फ़िगर करके, एक ही मॉड्यूल से अपने ऐप्लिकेशन के अलग-अलग वर्शन बनाए जा सकते हैं.

डाइनैमिक वर्शन कोड कॉन्फ़िगर करना

डिफ़ॉल्ट रूप से, जब Gradle आपके प्रोजेक्ट के लिए APK जनरेट करता है, तो हर APK में वर्शन की वही जानकारी होती है जो मॉड्यूल-लेवल की build.gradle फ़ाइल में दी गई है. Google Play Store, एक ही ऐप्लिकेशन के लिए एक से ज़्यादा APK अपलोड करने की अनुमति नहीं देता. ऐसा इसलिए, क्योंकि सभी APK में वर्शन की एक ही जानकारी होती है. इसलिए, Play Store पर अपलोड करने से पहले, आपको यह पक्का करना होगा कि हर APK का अपना यूनीक versionCode हो.

ऐसा कस्टम बिल्ड लॉजिक की मदद से किया जा सकता है, जो बिल्ड के समय हर APK को एक अलग वर्शन कोड असाइन करता है. उदाहरण के लिए, हर एबीआई के लिए अलग-अलग APK बनाते समय, APK का वर्शन अपने-आप इस तरह दिखता है:

Groovy

android {
  ...
  defaultConfig {
    ...
    versionCode 4
  }
  splits {
    ...
  }
}

// Map for the version code that gives each ABI a value.
ext.abiCodes = ['armeabi-v7a':1, mips:2, x86:3]

// For per-density APKs, create a similar map like this:
// ext.densityCodes = ['hdpi': 1, 'xhdpi': 2, 'xxhdpi': 3, 'xxxhdpi': 4]

import com.android.build.OutputFile

// For each APK output variant, override versionCode with a combination of
// ext.abiCodes * 1000 + variant.versionCode. In this example, variant.versionCode
// is equal to defaultConfig.versionCode. If you configure product flavors that
// define their own versionCode, variant.versionCode uses that value instead.
android.applicationVariants.all { variant ->

  // Assigns a different version code for each output APK
  // other than the universal APK.
  variant.outputs.each { output ->

    // Stores the value of ext.abiCodes that is associated with the ABI for this variant.
    def baseAbiVersionCode =
            // Determines the ABI for this variant and returns the mapped value.
            project.ext.abiCodes.get(output.getFilter(OutputFile.ABI))

    // Because abiCodes.get() returns null for ABIs that are not mapped by ext.abiCodes,
    // the following code does not override the version code for universal APKs.
    // However, because we want universal APKs to have the lowest version code,
    // this outcome is desirable.
    if (baseAbiVersionCode != null) {

      // Assigns the new version code to versionCodeOverride, which changes the version code
      // for only the output APK, not for the variant itself. Skipping this step simply
      // causes Gradle to use the value of variant.versionCode for the APK.
      output.versionCodeOverride =
              baseAbiVersionCode * 1000 + variant.versionCode
    }
  }
}

Kotlin

android {
  ...
  defaultConfig {
    ...
    versionCode = 4
  }
  splits {
    ...
  }
}

// Map for the version code that gives each ABI a value.
val abiCodes = mapOf("armeabi-v7a" to 1, "mips" to 2, "x86" to 3)

// For per-density APKs, create a similar map like this:
// val densityCodes = mapOf("hdpi" to 1, "xhdpi" to 2, "xxhdpi" to 3, "xxxhdpi" to 4)

import com.android.build.api.variant.FilterConfiguration.FilterType.*

// For each APK output variant, override versionCode with a combination of
// abiCodes * 1000 + variant.versionCode. In this example, variant.versionCode
// is equal to defaultConfig.versionCode. If you configure product flavors that
// define their own versionCode, variant.versionCode uses that value instead.
androidComponents {
    onVariants { variant ->

        // Assigns a different version code for each output APK
        // other than the universal APK.
        variant.outputs.forEach { output ->
            val name = output.filters.find { it.filterType == ABI }?.identifier

            // Stores the value of abiCodes that is associated with the ABI for this variant.
            val baseAbiCode = abiCodes[name]
            // Because abiCodes.get() returns null for ABIs that are not mapped by ext.abiCodes,
            // the following code does not override the version code for universal APKs.
            // However, because we want universal APKs to have the lowest version code,
            // this outcome is desirable.
            if (baseAbiCode != null) {
                // Assigns the new version code to output.versionCode, which changes the version code
                // for only the output APK, not for the variant itself.
                output.versionCode.set(baseAbiCode * 1000 + (output.versionCode.get() ?: 0))
            }
        }
    }
}

एक से ज़्यादा प्रॉडक्ट फ़्लेवर को जोड़ना

कुछ मामलों में, आपको कई प्रॉडक्ट फ़्लेवर के कॉन्फ़िगरेशन को एक साथ जोड़ना पड़ सकता है. इसके लिए, Gradle के लिए Android प्लग इन की मदद से, प्रॉडक्ट के फ़्लेवर के ग्रुप बनाए जा सकते हैं. इन्हें फ़्लेवर डाइमेंशन कहा जाता है.

यहां दिया गया कोड सैंपल, flavorDimensions प्रॉपर्टी का इस्तेमाल करके, "mode" फ़्लेवर डाइमेंशन बनाता है. इससे "full" और "demo" प्रॉडक्ट फ़्लेवर को ग्रुप किया जा सकता है. साथ ही, "api" फ़्लेवर डाइमेंशन बनाकर, एपीआई लेवल के आधार पर प्रॉडक्ट फ़्लेवर कॉन्फ़िगरेशन को ग्रुप किया जा सकता है. इसके बाद, Gradle "mode" डाइमेंशन के प्रॉडक्ट फ़्लेवर को "api" डाइमेंशन के प्रॉडक्ट फ़्लेवर के साथ जोड़ता है.

Groovy

android {
  ...
  buildTypes {
    debug {...}
    release {...}
  }

  // Specifies the flavor dimensions you want to use. The order in which you
  // list each dimension determines its priority, from highest to lowest,
  // when Gradle merges variant sources and configurations. You must assign
  // each product flavor you configure to one of the flavor dimensions.
  flavorDimensions "api", "mode"

  productFlavors {
    demo {
      // Assigns this product flavor to the "mode" flavor dimension.
      dimension "mode"
      ...
    }

    full {
      dimension "mode"
      ...
    }

    // Configurations in the "api" product flavors override those in "mode"
    // flavors and the defaultConfig block. Gradle determines the priority
    // between flavor dimensions based on the order in which they appear next
    // to the flavorDimensions property above--the first dimension has a higher
    // priority than the second, and so on.
    minApi24 {
      dimension "api"
      minSdkVersion '24'
      // To ensure the target device receives the version of the app with
      // the highest compatible API level, assign version codes in increasing
      // value with API level. To learn more about assigning version codes to
      // support app updates and uploading to Google Play, read Multiple APK Support
      versionCode 30000 + android.defaultConfig.versionCode
      versionNameSuffix "-minApi24"
      ...
    }

    minApi23 {
      dimension "api"
      minSdkVersion '23'
      versionCode 20000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi23"
      ...
    }

    minApi21 {
      dimension "api"
      minSdkVersion '21'
      versionCode 10000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi21"
      ...
    }
  }
}
...

Kotlin

android {
  ...
  buildTypes {
    getByName("debug") {...}
    getByName("release") {...}
  }

  // Specifies the flavor dimensions you want to use. The order in which you
  // list each dimension determines its priority, from highest to lowest,
  // when Gradle merges variant sources and configurations. You must assign
  // each product flavor you configure to one of the flavor dimensions.
  flavorDimensions += listOf("api", "mode")

  productFlavors {
    create("demo") {
      // Assigns this product flavor to the "mode" flavor dimension.
      dimension = "mode"
      ...
    }

    create("full") {
      dimension = "mode"
      ...
    }

    // Configurations in the "api" product flavors override those in "mode"
    // flavors and the defaultConfig block. Gradle determines the priority
    // between flavor dimensions based on the order in which they appear next
    // to the flavorDimensions property above--the first dimension has a higher
    // priority than the second, and so on.
    create("minApi24") {
      dimension = "api"
      minSdkVersion(24)
      // To ensure the target device receives the version of the app with
      // the highest compatible API level, assign version codes in increasing
      // value with API level. To learn more about assigning version codes to
      // support app updates and uploading to Google Play, read Multiple APK Support
      versionCode = 30000 + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi24"
      ...
    }

    create("minApi23") {
      dimension = "api"
      minSdkVersion(23)
      versionCode = 20000  + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi23"
      ...
    }

    create("minApi21") {
      dimension = "api"
      minSdkVersion(21)
      versionCode = 10000  + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi21"
      ...
    }
  }
}
...

वैरिएंट फ़िल्टर करना

मॉड्यूल की build.gradle फ़ाइल में मौजूद variantFilter ब्लॉक का इस्तेमाल करके, उन बिल्ड वैरिएंट को फ़िल्टर किया जा सकता है जिन्हें आपको नहीं चाहिए. यहां दिया गया सैंपल कोड, Gradle को "minApi21" और "demo" प्रॉडक्ट फ़्लेवर को मिलाकर कोई भी वैरिएंट बनाने से मना करता है:

Groovy

android {
  ...
  buildTypes {...}

  flavorDimensions "api", "mode"
  productFlavors {
    demo {...}
    full {...}
    minApi24 {...}
    minApi23 {...}
    minApi21 {...}
  }

  variantFilter { variant ->
      def names = variant.flavors*.name
      // To check for a certain build type, use variant.buildType.name == "<buildType>"
      if (names.contains("minApi21") && names.contains("demo")) {
          // Gradle ignores any variants that satisfy the conditions above.
          setIgnore(true)
      }
  }
}
...

Kotlin

android {
  ...
  buildTypes {...}

  flavorDimensions "api", "mode"
  productFlavors {
    create("demo") {...}
    create("full") {...}
    create("minApi24") {...}
    create("minApi23") {...}
    create("minApi21") {...}
  }
}

androidComponents {
    beforeVariants { variantBuilder ->
        // To check for a certain build type, use variantBuilder.buildType == "<buildType>"
        if (variantBuilder.productFlavors.containsAll(listOf("api" to "minApi21", "mode" to "demo"))) {
            // Gradle ignores any variants that satisfy the conditions above.
            variantBuilder.enabled = false
        }
    }
}
...

अपने ऐप्लिकेशन की जांच करना

लोकल और इंटिग्रेट की गई यूनिट टेस्ट चलाने के बारे में ज़्यादा जानने के लिए, अपने ऐप्लिकेशन की जांच करना लेख पढ़ें.

लिंट करने के विकल्प कॉन्फ़िगर करना

मॉड्यूल-लेवल की build.gradle फ़ाइल में lintOptions ब्लॉक का इस्तेमाल करके, कुछ लिंट विकल्पों को कॉन्फ़िगर किया जा सकता है. अपने Android प्रोजेक्ट के लिए, लिंट का इस्तेमाल करने के बारे में ज़्यादा जानने के लिए, लिंट की मदद से अपने कोड को बेहतर बनाएं लेख पढ़ें.

Groovy

android {
    ...
    lintOptions {
        // Turns off checks for the issue IDs you specify.
        disable 'TypographyFractions','TypographyQuotes'
        // Turns on checks for the issue IDs you specify. These checks are in
        // addition to the default lint checks.
        enable 'RtlHardcoded','RtlCompat', 'RtlEnabled'
        // To enable checks for only a subset of issue IDs and ignore all others,
        // list the issue IDs with the 'check' property instead. This property overrides
        // any issue IDs you enable or disable using the properties above.
        checkOnly 'NewApi', 'InlinedApi'
        // If set to true, turns off analysis progress reporting by lint.
        quiet true
        // if set to true (default), stops the build if errors are found.
        abortOnError false
        // if true, only report errors.
        ignoreWarnings true
    }
}
...

Kotlin

android {
    ...
    lintOptions {
        // Turns off checks for the issue IDs you specify.
        disable("TypographyFractions")
        disable("TypographyQuotes")
        // Turns on checks for the issue IDs you specify. These checks are in
        // addition to the default lint checks.
        enable("RtlHardcoded")
        enable("RtlCompat")
        enable("RtlEnabled")
        // To enable checks for only a subset of issue IDs and ignore all others,
        // list the issue IDs with the 'check' property instead. This property overrides
        // any issue IDs you enable or disable using the properties above.
        checkOnly("NewApi", "InlinedApi")
        // If set to true, turns off analysis progress reporting by lint.
        quiet = true
        // if set to true (default), stops the build if errors are found.
        abortOnError = false
        // if true, only report errors.
        ignoreWarnings = true
    }
}
...

इंस्ट्रुमेंटेशन मेनिफ़ेस्ट की सेटिंग कॉन्फ़िगर करना

जब Gradle आपके टेस्ट APK को बनाता है, तो वह AndroidManifest.xml फ़ाइल को अपने-आप जनरेट करता है और उसे <instrumentation> node के साथ कॉन्फ़िगर करता है. इस नोड की कुछ सेटिंग बदली जा सकती हैं. इसके लिए, टेस्ट सोर्स सेट में एक और मेनिफ़ेस्ट फ़ाइल बनाएं या अपने मॉड्यूल-लेवल की build.gradle फ़ाइल को कॉन्फ़िगर करें. इसके बारे में, नीचे दिए गए कोड सैंपल में बताया गया है.

Groovy

android {
  ...
  // Each product flavor you configure can override properties in the
  // defaultConfig block. To learn more, go to Configure Product Flavors.
  defaultConfig {
    ...
    // Specifies the application ID for the test APK.
    testApplicationId "com.test.foo"
    // Specifies the fully-qualified class name of the test instrumentation runner.
    testInstrumentationRunner "android.test.InstrumentationTestRunner"
    // If set to 'true', enables the instrumentation class to start and stop profiling.
    // If set to false (default), profiling occurs the entire time the instrumentation
    // class is running.
    testHandleProfiling true
    // If set to 'true', indicates that the Android system should run the instrumentation
    // class as a functional test. The default value is 'false'
    testFunctionalTest true
  }
}
...

Kotlin

android {
  ...
  // Each product flavor you configure can override properties in the
  // defaultConfig block. To learn more, go to Configure Product Flavors.
  defaultConfig {
    ...
    // Specifies the application ID for the test APK.
    testApplicationId = "com.test.foo"
    // Specifies the fully-qualified class name of the test instrumentation runner.
    testInstrumentationRunner = "android.test.InstrumentationTestRunner"
    // If set to 'true', enables the instrumentation class to start and stop profiling.
    // If set to false (default), profiling occurs the entire time the instrumentation
    // class is running.
    testHandleProfiling = true
    // If set to 'true', indicates that the Android system should run the instrumentation
    // class as a functional test. The default value is 'false'
    testFunctionalTest = true
  }
}
...

टेस्ट बिल्ड का टाइप बदलना

डिफ़ॉल्ट रूप से, सभी टेस्ट डीबग बिल्ड टाइप के लिए चलते हैं. अपने मॉड्यूल-लेवल की build.gradle फ़ाइल में testBuildType प्रॉपर्टी का इस्तेमाल करके, इसे किसी दूसरे टाइप के बिल्ड में बदला जा सकता है. उदाहरण के लिए, अगर आपको "स्टैजिंग" बिल्ड टाइप के लिए अपने टेस्ट चलाने हैं, तो नीचे दिए गए स्निपेट में दिखाए गए तरीके से फ़ाइल में बदलाव करें.

Groovy

android {
    ...
    testBuildType "staging"
}

Kotlin

android {
    ...
    testBuildType "staging"
}

Gradle टेस्ट के विकल्प कॉन्फ़िगर करना

Gradle के सभी टेस्ट चलाने के तरीके में बदलाव करने वाले विकल्पों को तय करने के लिए, मॉड्यूल-लेवल के build.gradle में testOptions ब्लॉक को कॉन्फ़िगर करें.

Groovy

android {
  ...
  // Encapsulates options for running tests.
  testOptions {
    // Changes the directory where Gradle saves test reports. By default, Gradle saves test reports
    // in the path_to_your_project/module_name/build/outputs/reports/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    reportDir "$rootDir/test-reports"
    // Changes the directory where Gradle saves test results. By default, Gradle saves test results
    // in the path_to_your_project/module_name/build/outputs/test-results/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    resultsDir "$rootDir/test-results"
  }
}

Kotlin

android {
  ...
  // Encapsulates options for running tests.
  testOptions {
    // Changes the directory where Gradle saves test reports. By default, Gradle saves test reports
    // in the path_to_your_project/module_name/build/outputs/reports/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    reportDir "$rootDir/test-reports"
    // Changes the directory where Gradle saves test results. By default, Gradle saves test results
    // in the path_to_your_project/module_name/build/outputs/test-results/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    resultsDir "$rootDir/test-results"
  }
}

सिर्फ़ लोकल यूनिट टेस्ट के लिए विकल्प तय करने के लिए, testOptions.unitTests ब्लॉक को कॉन्फ़िगर करें.

Groovy

android {
  ...
  testOptions {
    ...
    // Encapsulates options for local unit tests.
    unitTests {
      // By default, local unit tests throw an exception any time the code you are testing tries to access
      // Android platform APIs (unless you mock Android dependencies yourself or with a testing
      // framework like Mockito). However, you can enable the following property so that the test
      // returns either null or zero when accessing platform APIs, rather than throwing an exception.
      returnDefaultValues true

      // Encapsulates options for controlling how Gradle executes local unit tests. For a list
      // of all the options you can specify, read Gradle's reference documentation.
      all {
        // Sets JVM argument(s) for the test JVM(s).
        jvmArgs '-XX:MaxPermSize=256m'

        // You can also check the task name to apply options to only the tests you specify.
        if (it.name == 'testDebugUnitTest') {
          systemProperty 'debug', 'true'
        }
      }
    }
  }
}

Kotlin

android {
  ...
  testOptions {
    ...
    // Encapsulates options for local unit tests.
    unitTests {
      // By default, local unit tests throw an exception any time the code you are testing tries to access
      // Android platform APIs (unless you mock Android dependencies yourself or with a testing
      // framework like Mockito). However, you can enable the following property so that the test
      // returns either null or zero when accessing platform APIs, rather than throwing an exception.
      returnDefaultValues true

      // Encapsulates options for controlling how Gradle executes local unit tests. For a list
      // of all the options you can specify, read Gradle's reference documentation.
      all {
        // Sets JVM argument(s) for the test JVM(s).
        jvmArgs '-XX:MaxPermSize=256m'

        // You can also check the task name to apply options to only the tests you specify.
        if (it.name == 'testDebugUnitTest') {
          systemProperty 'debug', 'true'
        }
      }
    }
  }
}

अपना बिल्ड ऑप्टिमाइज़ करना

इस सेक्शन में कुछ कॉन्फ़िगरेशन दिए गए हैं. इनकी मदद से, पूरे और इंक्रीमेंटल बिल्ड को तेज़ी से पूरा किया जा सकता है. ज़्यादा जानने के लिए, पढ़ें बिल्ड की स्पीड ऑप्टिमाइज़ करना.

अपना कोड छोटा करना

Android Studio, R8 का इस्तेमाल करता है. यह आपके कोड को छोटा करने के लिए, ProGuard के नियमों की फ़ाइलों का इस्तेमाल करता है. नए प्रोजेक्ट के लिए, Android Studio, Android SDK के tools/proguard/folder से डिफ़ॉल्ट सेटिंग फ़ाइल (proguard-android.txt) का इस्तेमाल करता है. कोड को और छोटा करने के लिए, उसी जगह पर मौजूद proguard-android-optimize.txt फ़ाइल आज़माएं.

Groovy

android {
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'),
                                           'proguard-rules.pro'
    }
  }
  ...
}
...

Kotlin

android {
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'),
                                           'proguard-rules.pro'
    }
  }
  ...
}
...

हर बिल्ड वैरिएंट के लिए खास नियम जोड़ने के लिए, हर फ़्लेवर के लिए एक और proguardFiles प्रॉपर्टी कॉन्फ़िगर करें. उदाहरण के लिए, यहां दिया गया सैंपल, "flavor2" में flavor2-rules.pro जोड़ता है. अब "flavor2" के रिलीज़ वर्शन में, तीनों नियम फ़ाइलों का इस्तेमाल किया जाता है, क्योंकि रिलीज़ ब्लॉक की फ़ाइलें भी लागू होती हैं.

Groovy

android {
  ...
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android.txt'),
             'proguard-rules.pro'
    }
  }
  productFlavors {
    flavor1 {
      ...
    }
    flavor2 {
      proguardFile 'flavor2-rules.pro'
    }
  }
}
...

Kotlin

android {
  ...
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android.txt'),
             'proguard-rules.pro'
    }
  }
  productFlavors {
    flavor1 {
      ...
    }
    flavor2 {
      proguardFile 'flavor2-rules.pro'
    }
  }
}
...

ऐप्लिकेशन को पब्लिश करना

Google Play पर अपना ऐप्लिकेशन पब्लिश करने के बारे में ज़्यादा जानने के लिए, अपना ऐप्लिकेशन पब्लिश करना लेख पढ़ें.

अपने ऐप्लिकेशन पर हस्ताक्षर करना

Android Studio, यूज़र इंटरफ़ेस (यूआई) से रिलीज़ के लिए साइन करने की सुविधा को कॉन्फ़िगर करने का आसान तरीका उपलब्ध कराता है. हालांकि, अपने मॉड्यूल की build.gradle फ़ाइल में signingConfigs ब्लॉक को मैन्युअल तरीके से कॉन्फ़िगर किया जा सकता है:

Groovy

android {
  ...
  defaultConfig { ... }

  // Encapsulates signing configurations.
  signingConfigs {
    // Creates a signing configuration called "release".
    release {
      // Specifies the path to your keystore file.
      storeFile file("my-release-key.jks")
      // Specifies the password for your keystore.
      storePassword "password"
      // Specifies the identifying name for your key.
      keyAlias "my-alias"
      // Specifies the password for your key.
      keyPassword "password"
    }
  }
  buildTypes {
    release {
      // Adds the "release" signing configuration to the release build type.
      signingConfig signingConfigs.release
      ...
    }
  }
}
...

Kotlin

android {
  ...
  defaultConfig { ... }

  // Encapsulates signing configurations.
  signingConfigs {
    // Creates a signing configuration called "release".
    release {
      // Specifies the path to your keystore file.
      storeFile file("my-release-key.jks")
      // Specifies the password for your keystore.
      storePassword "password"
      // Specifies the identifying name for your key.
      keyAlias "my-alias"
      // Specifies the password for your key.
      keyPassword "password"
    }
  }
  buildTypes {
    release {
      // Adds the "release" signing configuration to the release build type.
      signingConfig signingConfigs.release
      ...
    }
  }
}
...

अपने प्रोजेक्ट से निजी हस्ताक्षर करने की जानकारी हटाना

डिफ़ॉल्ट रूप से, हस्ताक्षर करने के कॉन्फ़िगरेशन, मॉड्यूल की build.gradle फ़ाइल में सादे टेक्स्ट में रिकॉर्ड किए जाते हैं. अगर किसी टीम या किसी ओपन-सोर्स प्रोजेक्ट के साथ काम किया जा रहा है, तो इस संवेदनशील जानकारी को बिल्ड फ़ाइलों से हटाया जा सकता है. इसके लिए, यह तरीका अपनाएं.

अपने प्रोजेक्ट की रूट डायरेक्ट्री में keystore.properties नाम की फ़ाइल बनाएं और इसमें यह जानकारी शामिल करें:
```
storePassword=myStorePassword
keyPassword=myKeyPassword
keyAlias=myKeyAlias
storeFile=myStoreFileLocation
```

अपनी build.gradle फ़ाइल में, keystore.properties फ़ाइल को इस तरह लोड करें (यह Android ब्लॉक से पहले होना चाहिए):

Groovy

// Creates a variable called keystorePropertiesFile, and initializes it to the
// keystore.properties file.
def keystorePropertiesFile = rootProject.file("keystore.properties")

// Initializes a new Properties() object called keystoreProperties.
def keystoreProperties = new Properties()

// Loads the keystore.properties file into the keystoreProperties object.
keystoreProperties.load(new FileInputStream(keystorePropertiesFile))

android {
  ...
}
...

Kotlin

// Creates a variable called keystorePropertiesFile, and initializes it to the
// keystore.properties file.
def keystorePropertiesFile = rootProject.file("keystore.properties")

// Initializes a new Properties() object called keystoreProperties.
def keystoreProperties = new Properties()

// Loads the keystore.properties file into the keystoreProperties object.
keystoreProperties.load(new FileInputStream(keystorePropertiesFile))

android {
  ...
}
...

keystoreProperties ऑब्जेक्ट में सेव की गई, हस्ताक्षर करने की जानकारी डालें:

Groovy

android {
  signingConfigs {
    config {
      keyAlias keystoreProperties['keyAlias']
      keyPassword keystoreProperties['keyPassword']
      storeFile file(keystoreProperties['storeFile'])
      storePassword keystoreProperties['storePassword']
    }
  }
  ...
}
...

Kotlin

android {
  signingConfigs {
    config {
      keyAlias keystoreProperties['keyAlias']
      keyPassword keystoreProperties['keyPassword']
      storeFile file(keystoreProperties['storeFile'])
      storePassword keystoreProperties['storePassword']
    }
  }
  ...
}
...

सूचना बार में, अभी सिंक करें पर क्लिक करें.

ऐप्लिकेशन साइनिंग के बारे में ज़्यादा जानने के लिए, अपने ऐप्लिकेशन पर हस्ताक्षर करना लेख पढ़ें.

ऐप्लिकेशन डेवलपमेंट को आसान बनाना

यहां दी गई सलाह अपनाकर, Android ऐप्लिकेशन को आसानी से डेवलप किया जा सकता है.

बिल्ड के समय, Gradle BuildConfig क्लास जनरेट करता है, ताकि आपका ऐप्लिकेशन कोड, मौजूदा बिल्ड की जानकारी की जांच कर सके. buildConfigField() तरीके का इस्तेमाल करके, अपनी Gradle बिल्ड कॉन्फ़िगरेशन फ़ाइल से BuildConfig क्लास में कस्टम फ़ील्ड भी जोड़े जा सकते हैं. साथ ही, अपने ऐप्लिकेशन के रनटाइम कोड में उन वैल्यू को ऐक्सेस किया जा सकता है. इसी तरह, resValue() की मदद से ऐप्लिकेशन के संसाधन की वैल्यू भी जोड़ी जा सकती हैं.

Groovy

android {
  ...
  buildTypes {
    release {
      // These values are defined only for the release build, which
      // is typically used for full builds and continuous builds.
      buildConfigField("String", "BUILD_TIME", "\"${minutesSinceEpoch}\"")
      resValue("string", "build_time", "${minutesSinceEpoch}")
      ...
    }
    debug {
      // Use static values for incremental builds to ensure that
      // resource files and BuildConfig aren't rebuilt with each run.
      // If these rebuild dynamically, they can interfere with
      // Apply Changes as well as Gradle UP-TO-DATE checks.
      buildConfigField("String", "BUILD_TIME", "\"0\"")
      resValue("string", "build_time", "0")
    }
  }
}
...

Kotlin

android {
  ...
  buildTypes {
    release {
      // These values are defined only for the release build, which
      // is typically used for full builds and continuous builds.
      buildConfigField("String", "BUILD_TIME", "\"${minutesSinceEpoch}\"")
      resValue("string", "build_time", "${minutesSinceEpoch}")
      ...
    }
    debug {
      // Use static values for incremental builds to ensure that
      // resource files and BuildConfig aren't rebuilt with each run.
      // If these rebuild dynamically, they can interfere with
      // Apply Changes as well as Gradle UP-TO-DATE checks.
      buildConfigField("String", "BUILD_TIME", "\"0\"")
      resValue("string", "build_time", "0")
    }
  }
}
...

अपने ऐप्लिकेशन कोड में, प्रॉपर्टी को इस तरह ऐक्सेस किया जा सकता है:

Kotlin

...
Log.i(TAG, BuildConfig.BUILD_TIME)
Log.i(TAG, getString(R.string.build_time))

Java

...
Log.i(TAG, BuildConfig.BUILD_TIME);
Log.i(TAG, getString(R.string.build_time));

कुछ मामलों में, आपको अपने मेनिफ़ेस्ट और कोड, दोनों में एक ही प्रॉपर्टी का एलान करना पड़ सकता है. उदाहरण के लिए, किसी FileProvider के लिए अनुमतियों का एलान करते समय. किसी बदलाव को दिखाने के लिए, एक ही प्रॉपर्टी को कई जगहों पर अपडेट करने के बजाय, अपने मॉड्यूल की build.gradle फ़ाइल में एक प्रॉपर्टी तय करें, ताकि वह मेनिफ़ेस्ट और आपके कोड, दोनों के लिए उपलब्ध हो. इस बारे में नीचे दिए गए सैंपल में बताया गया है. ज़्यादा जानने के लिए, मेनिफ़ेस्ट में बिल्ड वैरिएबल इंजेक्ट करना लेख पढ़ें.

Groovy

android {
  // For settings specific to a product flavor, configure these properties
  // for each flavor in the productFlavors block.
  defaultConfig {
    // Creates a property for the FileProvider authority.
    def filesAuthorityValue = applicationId + ".files"
    // Creates a placeholder property to use in the manifest.
    manifestPlaceholders =
      [filesAuthority: filesAuthorityValue]
      // Adds a new field for the authority to the BuildConfig class.
      buildConfigField("String",
                       "FILES_AUTHORITY",
                       "\"${filesAuthorityValue}\"")
  }
  ...
}
...

Kotlin

android {
  // For settings specific to a product flavor, configure these properties
  // for each flavor in the productFlavors block.
  defaultConfig {
    // Creates a property for the FileProvider authority.
    val filesAuthorityValue = applicationId + ".files"
    // Creates a placeholder property to use in the manifest.
    manifestPlaceholders["filesAuthority"] = filesAuthorityValue
      // Adds a new field for the authority to the BuildConfig class.
      buildConfigField("String",
                       "FILES_AUTHORITY",
                       "\"${filesAuthorityValue}\"")
  }
  ...
}
...

अपने मेनिफ़ेस्ट में, प्लेसहोल्डर को इस तरह ऐक्सेस करें:

<manifest>
  ...
  <application>
    ...
    <provider
      android:name="android.support.v4.content.FileProvider"
      android:authorities="${filesAuthority}"
      android:exported="false"
      android:grantUriPermissions="true">
      ...
    </provider>
  </application>
</manifest>

अपने ऐप्लिकेशन के कोड में FILES_AUTHORITY फ़ील्ड को ऐक्सेस करने का तरीका कुछ ऐसा दिखता है:

Kotlin

...
val contentUri: Uri = FileProvider.getUriForFile(context, BuildConfig.FILES_AUTHORITY, myFile)

Java

...
Uri contentUri = FileProvider.getUriForFile(getContext(),
  BuildConfig.FILES_AUTHORITY,
  myFile);

Gradle से जुड़ी सलाह और रेसिपी

प्रोजेक्ट और सोर्स मैनेज करना

सोर्स सेट के डिफ़ॉल्ट कॉन्फ़िगरेशन बदलना

Groovy

Kotlin

लाइब्रेरी और डिपेंडेंसी मैनेज करना

डिपेंडेंसी कॉन्फ़िगरेशन की मदद से, खास बिल्ड को टारगेट करना

Groovy

Kotlin

अपने ऐप्लिकेशन के अलग-अलग वर्शन बनाना

डाइनैमिक वर्शन कोड कॉन्फ़िगर करना

Groovy

Kotlin

एक से ज़्यादा प्रॉडक्ट फ़्लेवर को जोड़ना

Groovy

Kotlin

वैरिएंट फ़िल्टर करना

Groovy

Kotlin

अपने ऐप्लिकेशन की जांच करना

लिंट करने के विकल्प कॉन्फ़िगर करना

Groovy

Kotlin

इंस्ट्रुमेंटेशन मेनिफ़ेस्ट की सेटिंग कॉन्फ़िगर करना

Groovy

Kotlin

टेस्ट बिल्ड का टाइप बदलना

Groovy

Kotlin

Gradle टेस्ट के विकल्प कॉन्फ़िगर करना

Groovy

Kotlin

Groovy

Kotlin

अपना बिल्ड ऑप्टिमाइज़ करना

अपना कोड छोटा करना

Groovy

Kotlin

Groovy

Kotlin

ऐप्लिकेशन को पब्लिश करना

अपने ऐप्लिकेशन पर हस्ताक्षर करना

Groovy

Kotlin

अपने प्रोजेक्ट से निजी हस्ताक्षर करने की जानकारी हटाना

Groovy

Kotlin

Groovy

Kotlin

ऐप्लिकेशन डेवलपमेंट को आसान बनाना

अपने ऐप्लिकेशन के कोड के साथ कस्टम फ़ील्ड और संसाधन की वैल्यू शेयर करना

Groovy

Kotlin

Kotlin

Java

मेनिफ़ेस्ट के साथ प्रॉपर्टी शेयर करना

Groovy

Kotlin

Kotlin

Java