تمت ترجمة هذه الصفحة بواسطة Cloud Translation API‏.

نصائح ووصفات طعام للغراب

يوفّر Gradle ومكوّن Android الإضافي لمنصة Gradle طريقة مرنة لتجميع التطبيقات أو المكتبات على Android وتصميمها وتجميعها. تجمع هذه الصفحة بعض النصائح والإعدادات المفيدة لمساعدتك في الاستفادة إلى أقصى حدّ من كل إصدار. لمعرفة المزيد من المعلومات حول طرق زيادة سرعة الإصدارات، اطّلِع على المقالة تحسين سرعة الإصدار.

إذا كنت مستخدمًا جديدًا لتطبيق Gradle، يمكنك التعرّف على الأساسيات من خلال قراءة مقالة Configure Your Build (ضبط تصميمك). يمكنك أيضًا فحص المستندات المرجعية لـ DSL الخاصة بمكوّن Android الإضافي للاطّلاع على مزيد من المعلومات عن الخصائص المستخدمة في هذه الصفحة.

إدارة المشاريع والمصادر

في ما يلي بعض الإعدادات لإدارة وحدات مشروعك ومصادرها. للاطّلاع على مزيد من المعلومات حول إنشاء المشاريع والوحدات وإدارتها، يمكنك الاطّلاع على نظرة عامة على المشاريع.

تغيير إعدادات مجموعة المصادر التلقائية

يمكنك استخدام المجموعة sourceSets في ملف build.gradle على مستوى الوحدة لتغيير المكان الذي يبحث فيه Gradle عن جمع الملفات لكل مكوّن في مجموعة مصادر.

رائع

android {
  ...
  sourceSets {
    // Encapsulates configurations for the main source set.
    main {
      // Changes the directory for Java sources. The default directory is
      // 'src/main/java'.
      java.srcDirs = ['other/java']

      // When you list multiple directories, Gradle uses all of them to collect
      // sources. You should avoid specifying a directory which is a parent to one
      // or more other directories you specify.
      res.srcDirs = ['other/res1', 'other/res2']

      // For each source set, you can specify only one Android manifest.
      // The following points Gradle to a different manifest for this source set.
      manifest.srcFile 'other/AndroidManifest.xml'
      ...
    }

    // Create additional blocks to configure other source sets.
    androidTest {

      // If all the files for a source set are located under a single root
      // directory, you can specify that directory using the setRoot property.
      // When gathering sources for the source set, Gradle looks only in locations
      // relative to the root directory you specify. For example, after applying
      // the configuration below for the androidTest source set, Gradle looks for
      // Java sources only in the src/tests/java/ directory.
      setRoot 'src/tests'
      ...
    }
  }
}
...

Kotlin

android {
  ...
  sourceSets {
    // Encapsulates configurations for the main source set.
    getByName("main") {
      // Changes the directory for Java sources. The default directory is
      // 'src/main/java'.
      java.setSrcDirs("other/java")

      // When you list multiple directories, Gradle uses all of them to collect
      // sources. You should avoid specifying a directory which is a parent to one
      // or more other directories you specify.
      res.setSrcDirs("other/res1", "other/res2")

      // For each source set, you can specify only one Android manifest.
      // The following points Gradle to a different manifest for this source set.
      manifest.srcFile("other/AndroidManifest.xml")
      ...
    }

    // Create additional blocks to configure other source sets.
    androidTest {

      // If all the files for a source set are located under a single root
      // directory, you can specify that directory using the setRoot property.
      // When gathering sources for the source set, Gradle looks only in locations
      // relative to the root directory you specify. For example, after applying
      // the configuration below for the androidTest source set, Gradle looks for
      // Java sources only in the src/tests/java/ directory.
      setRoot("src/tests")
      ...
    }
  }
}
...

إدارة المكتبات والتبعيات

توفّر أداة Gradle آلية فعّالة لإدارة الاعتماديات، سواء كانت مكتبات عن بُعد أو وحدات مكتبة محلية.

استهداف إصدارات معيّنة باستخدام إعدادات الاعتمادية

إذا كنت تريد اعتمادية لمجموعة مصدر صيغة معيّنة فقط أو مجموعة مصادر اختبار، أدخِل اسم إعدادات التبعية بالأحرف اللاتينية الكبيرة وضع في البداية اسم صيغة الإصدار أو مجموعة مصادر الاختبار.

رائع

android {...}

// Creates Gradle dependency configurations to use in the dependencies block.
configurations {
  // For variants that combine a product flavor and build type, you need to
  // intitialize a placeholder for its dependency configuration.
  freeDebugRuntimeOnly{}
  ...
}

dependencies {
    // Adds an implementation dependency only to the "free" product flavor.
    freeImplementation 'com.google.firebase:firebase-ads:21.5.1'
    // Adds a runtimeOnly dependency only to the "freeDebug" build variant.
    freeDebugRuntimeOnly fileTree(dir: 'libs', include: ['*.jar'])
    // Adds a remote binary dependency only for local tests.
    testImplementation 'junit:junit:4.12'
    // Adds a remote binary dependency only for the instrumented test APK.
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.5.1'
}

Kotlin

android {...}

dependencies {
    // Use ""() notation for custom flavors and build types
    // Adds an implementation dependency only to the "free" product flavor.
    "freeImplementation"("com.google.firebase:firebase-ads:21.5.1")
    // Adds a runtimeOnly dependency only to the "freeDebug" build variant.
    "freeDebugRuntimeOnly"(fileTree("dir" to "libs", "include" to "*.jar"))
    // Adds a remote binary dependency only for local tests.
    testImplementation("junit:junit:4.12")
    // Adds a remote binary dependency only for the instrumented test APK.
    androidTestImplementation("com.android.support.test.espresso:espresso-core:3.5.1")
}

إنشاء إصدارات مختلفة من تطبيقك

يسمح لك Gradle والمكوِّن الإضافي لنظام التشغيل Android بإنشاء إصدارات مختلفة من تطبيقك من وحدة واحدة من خلال ضبط صيغ الإصدار.

إعداد رموز الإصدارات الديناميكية

عندما ينشئ Gradle تلقائيًا ملفات APK لمشروعك، ستحتوي كل حِزمة APK على معلومات الإصدار نفسها على النحو المحدّد في ملف build.gradle على مستوى الوحدة. نظرًا لأن "متجر Google Play" لا يسمح بعدة حِزم APK للتطبيق نفسه التي تحتوي جميعها على معلومات الإصدار نفسها، يجب التأكد من أنّ كل حِزمة APK لها رمز versionCode فريد قبل تحميلها إلى متجر Play.

يمكنك إجراء ذلك باستخدام منطق تصميم مخصّص يحدّد رمز إصدار مختلف لكل ملف APK في وقت الإصدار. على سبيل المثال، عند إنشاء ملفات APK منفصلة لكل واجهة ABI، تبدو عملية تحديد إصدارات APK التلقائية على النحو التالي:

رائع

android {
  ...
  defaultConfig {
    ...
    versionCode 4
  }
  splits {
    ...
  }
}

// Map for the version code that gives each ABI a value.
ext.abiCodes = ['armeabi-v7a':1, mips:2, x86:3]

// For per-density APKs, create a similar map like this:
// ext.densityCodes = ['hdpi': 1, 'xhdpi': 2, 'xxhdpi': 3, 'xxxhdpi': 4]

import com.android.build.OutputFile

// For each APK output variant, override versionCode with a combination of
// ext.abiCodes * 1000 + variant.versionCode. In this example, variant.versionCode
// is equal to defaultConfig.versionCode. If you configure product flavors that
// define their own versionCode, variant.versionCode uses that value instead.
android.applicationVariants.all { variant ->

  // Assigns a different version code for each output APK
  // other than the universal APK.
  variant.outputs.each { output ->

    // Stores the value of ext.abiCodes that is associated with the ABI for this variant.
    def baseAbiVersionCode =
            // Determines the ABI for this variant and returns the mapped value.
            project.ext.abiCodes.get(output.getFilter(OutputFile.ABI))

    // Because abiCodes.get() returns null for ABIs that are not mapped by ext.abiCodes,
    // the following code does not override the version code for universal APKs.
    // However, because we want universal APKs to have the lowest version code,
    // this outcome is desirable.
    if (baseAbiVersionCode != null) {

      // Assigns the new version code to versionCodeOverride, which changes the version code
      // for only the output APK, not for the variant itself. Skipping this step simply
      // causes Gradle to use the value of variant.versionCode for the APK.
      output.versionCodeOverride =
              baseAbiVersionCode * 1000 + variant.versionCode
    }
  }
}

Kotlin

android {
  ...
  defaultConfig {
    ...
    versionCode = 4
  }
  splits {
    ...
  }
}

// Map for the version code that gives each ABI a value.
val abiCodes = mapOf("armeabi-v7a" to 1, "mips" to 2, "x86" to 3)

// For per-density APKs, create a similar map like this:
// val densityCodes = mapOf("hdpi" to 1, "xhdpi" to 2, "xxhdpi" to 3, "xxxhdpi" to 4)

import com.android.build.api.variant.FilterConfiguration.FilterType.*

// For each APK output variant, override versionCode with a combination of
// abiCodes * 1000 + variant.versionCode. In this example, variant.versionCode
// is equal to defaultConfig.versionCode. If you configure product flavors that
// define their own versionCode, variant.versionCode uses that value instead.
androidComponents {
    onVariants { variant ->

        // Assigns a different version code for each output APK
        // other than the universal APK.
        variant.outputs.forEach { output ->
            val name = output.filters.find { it.filterType == ABI }?.identifier

            // Stores the value of abiCodes that is associated with the ABI for this variant.
            val baseAbiCode = abiCodes[name]
            // Because abiCodes.get() returns null for ABIs that are not mapped by ext.abiCodes,
            // the following code does not override the version code for universal APKs.
            // However, because we want universal APKs to have the lowest version code,
            // this outcome is desirable.
            if (baseAbiCode != null) {
                // Assigns the new version code to output.versionCode, which changes the version code
                // for only the output APK, not for the variant itself.
                output.versionCode.set(baseAbiCode * 1000 + (output.versionCode.get() ?: 0))
            }
        }
    }
}

الجمع بين نكهات المنتجات المتعددة

وفي بعض الحالات، يمكنك دمج الإعدادات من نكهات متعددة للمنتجات. لإجراء ذلك، يتيح لك مكوّن Android الإضافي في Gradle إنشاء مجموعات من نكهات المنتجات تُسمى أبعاد النكهة.

يستخدم نموذج الرمز البرمجي التالي سمة flavorDimensions لإنشاء سمة نكهة "الوضع" لتجميع نكهات المنتج "الكاملة" و "الإصدار التجريبي"، وسمة صيغة "واجهة برمجة التطبيقات" لتجميع إعدادات نكهة المنتج استنادًا إلى مستوى واجهة برمجة التطبيقات. بعد ذلك، يجمع Gradle بعدها نكهات المنتجات من سمة "الوضع" نكهات المنتجات الخاصة بسمة "واجهة برمجة التطبيقات".

رائع

android {
  ...
  buildTypes {
    debug {...}
    release {...}
  }

  // Specifies the flavor dimensions you want to use. The order in which you
  // list each dimension determines its priority, from highest to lowest,
  // when Gradle merges variant sources and configurations. You must assign
  // each product flavor you configure to one of the flavor dimensions.
  flavorDimensions "api", "mode"

  productFlavors {
    demo {
      // Assigns this product flavor to the "mode" flavor dimension.
      dimension "mode"
      ...
    }

    full {
      dimension "mode"
      ...
    }

    // Configurations in the "api" product flavors override those in "mode"
    // flavors and the defaultConfig block. Gradle determines the priority
    // between flavor dimensions based on the order in which they appear next
    // to the flavorDimensions property above--the first dimension has a higher
    // priority than the second, and so on.
    minApi24 {
      dimension "api"
      minSdkVersion '24'
      // To ensure the target device receives the version of the app with
      // the highest compatible API level, assign version codes in increasing
      // value with API level. To learn more about assigning version codes to
      // support app updates and uploading to Google Play, read Multiple APK Support
      versionCode 30000 + android.defaultConfig.versionCode
      versionNameSuffix "-minApi24"
      ...
    }

    minApi23 {
      dimension "api"
      minSdkVersion '23'
      versionCode 20000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi23"
      ...
    }

    minApi21 {
      dimension "api"
      minSdkVersion '21'
      versionCode 10000  + android.defaultConfig.versionCode
      versionNameSuffix "-minApi21"
      ...
    }
  }
}
...

Kotlin

android {
  ...
  buildTypes {
    getByName("debug") {...}
    getByName("release") {...}
  }

  // Specifies the flavor dimensions you want to use. The order in which you
  // list each dimension determines its priority, from highest to lowest,
  // when Gradle merges variant sources and configurations. You must assign
  // each product flavor you configure to one of the flavor dimensions.
  flavorDimensions += listOf("api", "mode")

  productFlavors {
    create("demo") {
      // Assigns this product flavor to the "mode" flavor dimension.
      dimension = "mode"
      ...
    }

    create("full") {
      dimension = "mode"
      ...
    }

    // Configurations in the "api" product flavors override those in "mode"
    // flavors and the defaultConfig block. Gradle determines the priority
    // between flavor dimensions based on the order in which they appear next
    // to the flavorDimensions property above--the first dimension has a higher
    // priority than the second, and so on.
    create("minApi24") {
      dimension = "api"
      minSdkVersion(24)
      // To ensure the target device receives the version of the app with
      // the highest compatible API level, assign version codes in increasing
      // value with API level. To learn more about assigning version codes to
      // support app updates and uploading to Google Play, read Multiple APK Support
      versionCode = 30000 + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi24"
      ...
    }

    create("minApi23") {
      dimension = "api"
      minSdkVersion(23_
      versionCode = 20000  + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi23"
      ...
    }

    create("minApi21") {
      dimension = "api"
      minSdkVersion(21)
      versionCode = 10000  + android.defaultConfig.versionCode
      versionNameSuffix = "-minApi21"
      ...
    }
  }
}
...

فلترة الصيغ

يمكنك فلترة الصيغ التي لا تريدها باستخدام المجموعة variantFilter في ملف build.gradle الخاص بالوحدة. يطلب الرمز النموذجي التالي من Gradle عدم إنشاء أي خيارات تجمع بين نكهتَي المنتج "minApi21" و "demo":

رائع

android {
  ...
  buildTypes {...}

  flavorDimensions "api", "mode"
  productFlavors {
    demo {...}
    full {...}
    minApi24 {...}
    minApi23 {...}
    minApi21 {...}
  }

  variantFilter { variant ->
      def names = variant.flavors*.name
      // To check for a certain build type, use variant.buildType.name == "<buildType>"
      if (names.contains("minApi21") && names.contains("demo")) {
          // Gradle ignores any variants that satisfy the conditions above.
          setIgnore(true)
      }
  }
}
...

Kotlin

android {
  ...
  buildTypes {...}

  flavorDimensions "api", "mode"
  productFlavors {
    create("demo") {...}
    create("full") {...}
    create("minApi24") {...}
    create("minApi23") {...}
    create("minApi21") {...}
  }
}

androidComponents {
    beforeVariants { variantBuilder ->
        // To check for a certain build type, use variantBuilder.buildType == "<buildType>"
        if (variantBuilder.productFlavors.containsAll(listOf("api" to "minApi21", "mode" to "demo"))) {
            // Gradle ignores any variants that satisfy the conditions above.
            variantBuilder.enabled = false
        }
    }
}
...

اختبار تطبيقك

لمعرفة المزيد من المعلومات عن إجراء اختبارات الوحدات المحلية والمتكاملة، يمكنك الاطّلاع على اختبار تطبيقك.

ضبط خيارات أداة Lint

يمكنك ضبط خيارات أداة Lint على مستوى الوحدة باستخدام أداة lintOptions في ملف build.gradle على مستوى الوحدة. لمعرفة مزيد من المعلومات حول استخدام أداة Lint في مشروع Android، يُرجى الاطّلاع على المقالة تحسين الرمز باستخدام Lint.

رائع

android {
    ...
    lintOptions {
        // Turns off checks for the issue IDs you specify.
        disable 'TypographyFractions','TypographyQuotes'
        // Turns on checks for the issue IDs you specify. These checks are in
        // addition to the default lint checks.
        enable 'RtlHardcoded','RtlCompat', 'RtlEnabled'
        // To enable checks for only a subset of issue IDs and ignore all others,
        // list the issue IDs with the 'check' property instead. This property overrides
        // any issue IDs you enable or disable using the properties above.
        checkOnly 'NewApi', 'InlinedApi'
        // If set to true, turns off analysis progress reporting by lint.
        quiet true
        // if set to true (default), stops the build if errors are found.
        abortOnError false
        // if true, only report errors.
        ignoreWarnings true
    }
}
...

Kotlin

android {
    ...
    lintOptions {
        // Turns off checks for the issue IDs you specify.
        disable("TypographyFractions")
        disable("TypographyQuotes")
        // Turns on checks for the issue IDs you specify. These checks are in
        // addition to the default lint checks.
        enable("RtlHardcoded")
        enable("RtlCompat")
        enable("RtlEnabled")
        // To enable checks for only a subset of issue IDs and ignore all others,
        // list the issue IDs with the 'check' property instead. This property overrides
        // any issue IDs you enable or disable using the properties above.
        checkOnly("NewApi", "InlinedApi")
        // If set to true, turns off analysis progress reporting by lint.
        quiet = true
        // if set to true (default), stops the build if errors are found.
        abortOnError = false
        // if true, only report errors.
        ignoreWarnings = true
    }
}
...

ضبط إعدادات بيان الأدوات

عندما تنشئ Gradle حزمة APK التجريبية، فإنها تنشئ تلقائيًا ملف AndroidManifest.xml وتضبطه باستخدام العقدة <instrumentation>. يمكنك تغيير بعض إعدادات هذه العقدة عن طريق إنشاء ملف بيان آخر في مجموعة مصادر الاختبار أو ضبط ملف build.gradle على مستوى الوحدة، كما هو موضّح في نموذج الرمز التالي.

رائع

android {
  ...
  // Each product flavor you configure can override properties in the
  // defaultConfig block. To learn more, go to Configure Product Flavors.
  defaultConfig {
    ...
    // Specifies the application ID for the test APK.
    testApplicationId "com.test.foo"
    // Specifies the fully-qualified class name of the test instrumentation runner.
    testInstrumentationRunner "android.test.InstrumentationTestRunner"
    // If set to 'true', enables the instrumentation class to start and stop profiling.
    // If set to false (default), profiling occurs the entire time the instrumentation
    // class is running.
    testHandleProfiling true
    // If set to 'true', indicates that the Android system should run the instrumentation
    // class as a functional test. The default value is 'false'
    testFunctionalTest true
  }
}
...

Kotlin

android {
  ...
  // Each product flavor you configure can override properties in the
  // defaultConfig block. To learn more, go to Configure Product Flavors.
  defaultConfig {
    ...
    // Specifies the application ID for the test APK.
    testApplicationId = "com.test.foo"
    // Specifies the fully-qualified class name of the test instrumentation runner.
    testInstrumentationRunner = "android.test.InstrumentationTestRunner"
    // If set to 'true', enables the instrumentation class to start and stop profiling.
    // If set to false (default), profiling occurs the entire time the instrumentation
    // class is running.
    testHandleProfiling = true
    // If set to 'true', indicates that the Android system should run the instrumentation
    // class as a functional test. The default value is 'false'
    testFunctionalTest = true
  }
}
...

تغيير نوع الإصدار التجريبي

يتم تلقائيًا إجراء جميع الاختبارات على نوع إصدار تصحيح الأخطاء. يمكنك تغيير هذا إلى نوع تصميم آخر باستخدام السمة testBuildType في ملف build.gradle على مستوى الوحدة. على سبيل المثال، إذا كنت تريد إجراء اختباراتك على نوع الإصدار "تقسيم مرحلي"، عدِّل الملف كما هو موضّح في المقتطف التالي.

رائع

android {
    ...
    testBuildType "staging"
}

Kotlin

android {
    ...
    testBuildType "staging"
}

ضبط خيارات اختبار Gradle

لتحديد الخيارات التي تغيّر طريقة تنفيذ Gradle لجميع اختباراتك، يجب ضبط المجموعة testOptions في build.gradle على مستوى الوحدة.

رائع

android {
  ...
  // Encapsulates options for running tests.
  testOptions {
    // Changes the directory where Gradle saves test reports. By default, Gradle saves test reports
    // in the path_to_your_project/module_name/build/outputs/reports/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    reportDir "$rootDir/test-reports"
    // Changes the directory where Gradle saves test results. By default, Gradle saves test results
    // in the path_to_your_project/module_name/build/outputs/test-results/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    resultsDir "$rootDir/test-results"
  }
}

Kotlin

android {
  ...
  // Encapsulates options for running tests.
  testOptions {
    // Changes the directory where Gradle saves test reports. By default, Gradle saves test reports
    // in the path_to_your_project/module_name/build/outputs/reports/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    reportDir "$rootDir/test-reports"
    // Changes the directory where Gradle saves test results. By default, Gradle saves test results
    // in the path_to_your_project/module_name/build/outputs/test-results/ directory.
    // '$rootDir' sets the path relative to the root directory of the current project.
    resultsDir "$rootDir/test-results"
  }
}

لتحديد خيارات اختبارات الوحدات المحلية فقط، اضبط مجموعة testOptions.unitTests.

رائع

android {
  ...
  testOptions {
    ...
    // Encapsulates options for local unit tests.
    unitTests {
      // By default, local unit tests throw an exception any time the code you are testing tries to access
      // Android platform APIs (unless you mock Android dependencies yourself or with a testing
      // framework like Mockito). However, you can enable the following property so that the test
      // returns either null or zero when accessing platform APIs, rather than throwing an exception.
      returnDefaultValues true

      // Encapsulates options for controlling how Gradle executes local unit tests. For a list
      // of all the options you can specify, read Gradle's reference documentation.
      all {
        // Sets JVM argument(s) for the test JVM(s).
        jvmArgs '-XX:MaxPermSize=256m'

        // You can also check the task name to apply options to only the tests you specify.
        if (it.name == 'testDebugUnitTest') {
          systemProperty 'debug', 'true'
        }
      }
    }
  }
}

Kotlin

android {
  ...
  testOptions {
    ...
    // Encapsulates options for local unit tests.
    unitTests {
      // By default, local unit tests throw an exception any time the code you are testing tries to access
      // Android platform APIs (unless you mock Android dependencies yourself or with a testing
      // framework like Mockito). However, you can enable the following property so that the test
      // returns either null or zero when accessing platform APIs, rather than throwing an exception.
      returnDefaultValues true

      // Encapsulates options for controlling how Gradle executes local unit tests. For a list
      // of all the options you can specify, read Gradle's reference documentation.
      all {
        // Sets JVM argument(s) for the test JVM(s).
        jvmArgs '-XX:MaxPermSize=256m'

        // You can also check the task name to apply options to only the tests you specify.
        if (it.name == 'testDebugUnitTest') {
          systemProperty 'debug', 'true'
        }
      }
    }
  }
}

تحسين تصميمك

يقدّم هذا القسم بعض الإعدادات للمساعدة في تسريع الإصدارات الكاملة والتزايدية. للحصول على مزيد من المعلومات، يمكنك الاطّلاع على مقالة تحسين سرعة الإصدار.

تقليص الرمز

يستخدم "استوديو Android" الإصدار R8 الذي يستهلك ملفات قواعد ProGuard لتصغير حجم الرموز. بالنسبة إلى المشاريع الجديدة، يستخدم "استوديو Android" ملف الإعدادات التلقائي (proguard-android.txt) من tools/proguard/folder على حزمة تطوير البرامج (SDK) لنظام التشغيل Android. لتصغير حجم الرموز بشكل أكبر، جرِّب ملف proguard-android-optimize.txt المتوفّر في الموقع نفسه.

رائع

android {
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'),
                                           'proguard-rules.pro'
    }
  }
  ...
}
...

Kotlin

android {
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'),
                                           'proguard-rules.pro'
    }
  }
  ...
}
...

لإضافة قواعد خاصة بكل خيار من خيارات الإصدار، يجب ضبط سمة proguardFiles إضافية لكل نكهة. على سبيل المثال، يضيف النموذج التالي flavor2-rules.pro إلى "flavor2". تستخدم نسخة الإصدار من "flavor2" الآن جميع ملفات القواعد الثلاث، لأنّه يتم أيضًا تطبيق تلك الواردة من مجموعة الإصدار.

رائع

android {
  ...
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android.txt'),
             'proguard-rules.pro'
    }
  }
  productFlavors {
    flavor1 {
      ...
    }
    flavor2 {
      proguardFile 'flavor2-rules.pro'
    }
  }
}
...

Kotlin

android {
  ...
  buildTypes {
    release {
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android.txt'),
             'proguard-rules.pro'
    }
  }
  productFlavors {
    flavor1 {
      ...
    }
    flavor2 {
      proguardFile 'flavor2-rules.pro'
    }
  }
}
...

نشر التطبيق

لمزيد من المعلومات حول نشر تطبيقك على Google Play، يُرجى الاطّلاع على مقالة نشر التطبيق.

توقيع التطبيق

مع أنّ "استوديو Android" يوفّر طريقة سهلة لضبط عملية توقيع إصدارات الإصدارات من واجهة المستخدم، يمكنك ضبط مجموعة signingConfigs يدويًا في ملف build.gradle الخاص بالوحدة:

رائع

android {
  ...
  defaultConfig { ... }

  // Encapsulates signing configurations.
  signingConfigs {
    // Creates a signing configuration called "release".
    release {
      // Specifies the path to your keystore file.
      storeFile file("my-release-key.jks")
      // Specifies the password for your keystore.
      storePassword "password"
      // Specifies the identifying name for your key.
      keyAlias "my-alias"
      // Specifies the password for your key.
      keyPassword "password"
    }
  }
  buildTypes {
    release {
      // Adds the "release" signing configuration to the release build type.
      signingConfig signingConfigs.release
      ...
    }
  }
}
...

Kotlin

android {
  ...
  defaultConfig { ... }

  // Encapsulates signing configurations.
  signingConfigs {
    // Creates a signing configuration called "release".
    release {
      // Specifies the path to your keystore file.
      storeFile file("my-release-key.jks")
      // Specifies the password for your keystore.
      storePassword "password"
      // Specifies the identifying name for your key.
      keyAlias "my-alias"
      // Specifies the password for your key.
      keyPassword "password"
    }
  }
  buildTypes {
    release {
      // Adds the "release" signing configuration to the release build type.
      signingConfig signingConfigs.release
      ...
    }
  }
}
...

إزالة معلومات التوقيع الخاص من مشروعك

يتم تلقائيًا تسجيل عمليات ضبط التوقيع في نص عادي في ملف build.gradle الخاص بالوحدة. إذا كنت تعمل مع فريق أو مشروع مفتوح المصدر، يمكنك نقل هذه المعلومات الحساسة من ملفات الإصدار من خلال المتابعة على النحو التالي.

أنشئ ملفًا باسم keystore.properties في الدليل الجذري لمشروعك وضمِّن المعلومات التالية:
```
storePassword=myStorePassword
keyPassword=myKeyPassword
keyAlias=myKeyAlias
storeFile=myStoreFileLocation
```
.

في ملف build.gradle، يمكنك تحميل ملف keystore.properties على النحو التالي (يجب أن يكون ذلك قبل حظر Android):

رائع

// Creates a variable called keystorePropertiesFile, and initializes it to the
// keystore.properties file.
def keystorePropertiesFile = rootProject.file("keystore.properties")

// Initializes a new Properties() object called keystoreProperties.
def keystoreProperties = new Properties()

// Loads the keystore.properties file into the keystoreProperties object.
keystoreProperties.load(new FileInputStream(keystorePropertiesFile))

android {
  ...
}
...

Kotlin

// Creates a variable called keystorePropertiesFile, and initializes it to the
// keystore.properties file.
def keystorePropertiesFile = rootProject.file("keystore.properties")

// Initializes a new Properties() object called keystoreProperties.
def keystoreProperties = new Properties()

// Loads the keystore.properties file into the keystoreProperties object.
keystoreProperties.load(new FileInputStream(keystorePropertiesFile))

android {
  ...
}
...

أدخِل معلومات التوقيع المخزَّنة في العنصر keystoreProperties:

رائع

android {
  signingConfigs {
    config {
      keyAlias keystoreProperties['keyAlias']
      keyPassword keystoreProperties['keyPassword']
      storeFile file(keystoreProperties['storeFile'])
      storePassword keystoreProperties['storePassword']
    }
  }
  ...
}
...

Kotlin

android {
  signingConfigs {
    config {
      keyAlias keystoreProperties['keyAlias']
      keyPassword keystoreProperties['keyPassword']
      storeFile file(keystoreProperties['storeFile'])
      storePassword keystoreProperties['storePassword']
    }
  }
  ...
}
...

انقر على المزامنة الآن في شريط الإشعارات.

لمزيد من المعلومات عن ميزة "توقيع التطبيق"، يُرجى الاطّلاع على مقالة توقيع تطبيقك.

تبسيط تطوير التطبيقات

تساعد النصائح التالية في تسهيل تطوير تطبيق Android.

في وقت الإصدار، ينشئ Gradle الفئة BuildConfig حتى يتمكن رمز تطبيقك من فحص المعلومات المتعلقة بالإصدار الحالي. يمكنك أيضًا إضافة حقول مخصّصة إلى الفئة BuildConfig من ملف إعداد إصدار Gradle باستخدام طريقة buildConfigField() والوصول إلى تلك القيم في رمز وقت التشغيل لتطبيقك. وبالمثل، يمكنك إضافة قيم موارد التطبيقات باستخدام resValue().

رائع

android {
  ...
  buildTypes {
    release {
      // These values are defined only for the release build, which
      // is typically used for full builds and continuous builds.
      buildConfigField("String", "BUILD_TIME", "\"${minutesSinceEpoch}\"")
      resValue("string", "build_time", "${minutesSinceEpoch}")
      ...
    }
    debug {
      // Use static values for incremental builds to ensure that
      // resource files and BuildConfig aren't rebuilt with each run.
      // If these rebuild dynamically, they can interfere with
      // Apply Changes as well as Gradle UP-TO-DATE checks.
      buildConfigField("String", "BUILD_TIME", "\"0\"")
      resValue("string", "build_time", "0")
    }
  }
}
...

Kotlin

android {
  ...
  buildTypes {
    release {
      // These values are defined only for the release build, which
      // is typically used for full builds and continuous builds.
      buildConfigField("String", "BUILD_TIME", "\"${minutesSinceEpoch}\"")
      resValue("string", "build_time", "${minutesSinceEpoch}")
      ...
    }
    debug {
      // Use static values for incremental builds to ensure that
      // resource files and BuildConfig aren't rebuilt with each run.
      // If these rebuild dynamically, they can interfere with
      // Apply Changes as well as Gradle UP-TO-DATE checks.
      buildConfigField("String", "BUILD_TIME", "\"0\"")
      resValue("string", "build_time", "0")
    }
  }
}
...

في رمز التطبيق، يمكنك الوصول إلى المواقع على النحو التالي:

Kotlin

...
Log.i(TAG, BuildConfig.BUILD_TIME)
Log.i(TAG, getString(R.string.build_time))

Java

...
Log.i(TAG, BuildConfig.BUILD_TIME);
Log.i(TAG, getString(R.string.build_time));

في بعض الحالات، قد تحتاج إلى الإعلان عن السمة نفسها في كلّ من البيان والرمز الخاص بك (على سبيل المثال، عند توضيح الصلاحيات لـ FileProvider). وبدلاً من تعديل السمة نفسها في مواقع متعدّدة لتعكس تغييرًا، يمكنك تحديد سمة واحدة في ملف build.gradle الخاص بالوحدة لإتاحتها لكل من البيان والرمز الخاص بك، كما هو موضّح في النموذج التالي. للحصول على مزيد من المعلومات، راجِع إدخال متغيّرات الإصدار في ملف البيان.

رائع

android {
  // For settings specific to a product flavor, configure these properties
  // for each flavor in the productFlavors block.
  defaultConfig {
    // Creates a property for the FileProvider authority.
    def filesAuthorityValue = applicationId + ".files"
    // Creates a placeholder property to use in the manifest.
    manifestPlaceholders =
      [filesAuthority: filesAuthorityValue]
      // Adds a new field for the authority to the BuildConfig class.
      buildConfigField("String",
                       "FILES_AUTHORITY",
                       "\"${filesAuthorityValue}\"")
  }
  ...
}
...

Kotlin

android {
  // For settings specific to a product flavor, configure these properties
  // for each flavor in the productFlavors block.
  defaultConfig {
    // Creates a property for the FileProvider authority.
    val filesAuthorityValue = applicationId + ".files"
    // Creates a placeholder property to use in the manifest.
    manifestPlaceholders["filesAuthority"] = filesAuthorityValue
      // Adds a new field for the authority to the BuildConfig class.
      buildConfigField("String",
                       "FILES_AUTHORITY",
                       "\"${filesAuthorityValue}\"")
  }
  ...
}
...

في البيان، يمكنك الوصول إلى العنصر النائب على النحو التالي:

<manifest>
  ...
  <application>
    ...
    <provider
      android:name="android.support.v4.content.FileProvider"
      android:authorities="${filesAuthority}"
      android:exported="false"
      android:grantUriPermissions="true">
      ...
    </provider>
  </application>
</manifest>

يبدو الوصول إلى حقل FILES_AUTHORITY في رمز تطبيقك على النحو التالي:

Kotlin

...
val contentUri: Uri = FileProvider.getUriForFile(context, BuildConfig.FILES_AUTHORITY, myFile)

Java

...
Uri contentUri = FileProvider.getUriForFile(getContext(),
  BuildConfig.FILES_AUTHORITY,
  myFile);

نصائح ووصفات طعام للغراب

إدارة المشاريع والمصادر

تغيير إعدادات مجموعة المصادر التلقائية

رائع

Kotlin

إدارة المكتبات والتبعيات

استهداف إصدارات معيّنة باستخدام إعدادات الاعتمادية

رائع

Kotlin

إنشاء إصدارات مختلفة من تطبيقك

إعداد رموز الإصدارات الديناميكية

رائع

Kotlin

الجمع بين نكهات المنتجات المتعددة

رائع

Kotlin

فلترة الصيغ

رائع

Kotlin

اختبار تطبيقك

ضبط خيارات أداة Lint

رائع

Kotlin

ضبط إعدادات بيان الأدوات

رائع

Kotlin

تغيير نوع الإصدار التجريبي

رائع

Kotlin

ضبط خيارات اختبار Gradle

رائع

Kotlin

رائع

Kotlin

تحسين تصميمك

تقليص الرمز

رائع

Kotlin

رائع

Kotlin

نشر التطبيق

توقيع التطبيق

رائع

Kotlin

إزالة معلومات التوقيع الخاص من مشروعك

رائع

Kotlin

رائع

Kotlin

تبسيط تطوير التطبيقات

مشاركة الحقول المخصّصة وقيم الموارد مع رمز تطبيقك

رائع

Kotlin

Kotlin

Java

مشاركة الخصائص مع البيان

رائع

Kotlin

Kotlin

Java