빌드 변형 구성

이 페이지는 빌드 구성 개요를 토대로 하며, 단일 프로젝트에서 다양한 버전의 앱을 생성하기 위해 빌드 변형을 구성하는 방법과 종속성 및 서명 구성을 올바르게 관리하는 방법을 보여줍니다.

빌드 변형은 빌드할 수 있는 다른 버전의 앱을 나타냅니다. 예를 들어, 콘텐츠가 제한된 무료 버전의 앱을 빌드하고, 더 많은 콘텐츠가 포함된 유료 버전의 앱을 빌드할 수 있습니다. 또한 API 레벨이나 기타 기기 변화에 따라 다양한 기기에 맞게 서로 다른 버전의 앱을 빌드할 수도 있습니다. 그러나 기기 ABI나 화면 밀도에 따라 서로 다른 버전을 빌드하려는 경우에는 여러 APK를 빌드해야 합니다.

빌드 변형은 Gradle이 특정 규칙 세트를 사용하여 빌드 유형과 제품 버전에 구성된 설정, 코드 및 리소스를 조합한 결과입니다. 개발자는 빌드 변형을 직접 구성하는 것은 아니지만, 이를 형성하는 빌드 유형과 제품 버전을 구성하게 됩니다.

예를 들어, 'demo' 제품 버전에서는 다양한 기능과 기기 요구사항(예: 맞춤형 소스 코드, 리소스 및 최소 API 레벨)을 지정할 수 있는 반면, 'debug' 빌드 유형에서는 다양한 빌드 및 패키징 설정(예: 디버그 옵션 및 서명 키)을 적용할 수 있습니다. 결과로 생기는 빌드 변형은 'demoDebug' 버전의 앱이며 여기에는 'demo' 제품 버전, 'debug' 빌드 유형, 그리고 main/ 소스 세트에 포함된 구성 및 리소스의 조합이 포함됩니다.

빌드 유형 구성

모듈 레벨 build.gradle 파일의 android 블록 내에 빌드 유형을 생성하고 구성할 수 있습니다. 개발자가 새 모듈을 생성하면 Android 스튜디오가 개발자 대신 디버그 및 릴리스 빌드 유형을 자동으로 생성합니다. 디버그 빌드 유형이 빌드 구성 파일에 나타나지 않더라도, Android 스튜디오는 debuggable true로 이 빌드 유형을 구성합니다. 따라서 보안 Android 기기에서 앱을 디버깅할 수 있으며 일반 디버그 키 저장소로 APK 서명을 구성합니다.

특정 설정을 추가하거나 변경하려는 경우 디버그 빌드 유형을 자신의 구성에 추가할 수 있습니다. 다음 샘플에서는 디버그 빌드 유형에 applicationIdSuffix를 지정하고, 디버그 빌드 유형의 설정을 사용하여 초기화된 'staging' 빌드 유형을 구성합니다.

    android {
        defaultConfig {
            manifestPlaceholders = [hostName:"www.example.com"]
            ...
        }
        buildTypes {
            release {
                minifyEnabled true
                proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            }

            debug {
                applicationIdSuffix ".debug"
                debuggable true
            }

            /**
             * The `initWith` property allows you to copy configurations from other build types,
             * then configure only the settings you want to change. This one copies the debug build
             * type, and then changes the manifest placeholder and application ID.
             */
            staging {
                initWith debug
                manifestPlaceholders = [hostName:"internal.example.com"]
                applicationIdSuffix ".debugStaging"
            }
        }
    }
    

참고: 개발자가 빌드 구성 파일을 변경하면 Android 스튜디오는 프로젝트를 새 구성으로 동기화하도록 요청합니다. 프로젝트를 동기화하려면 변경하자마자 바로 나타나는 알림바에서 Sync Now를 클릭하거나 툴바에서 Sync Project 를 클릭합니다. Android 스튜디오에서 구성 오류가 발견되면, 문제가 무엇인지 설명해주는 Messages 창이 나타납니다.

빌드 유형에서 구성할 수 있는 모든 속성에 관해 자세히 알아보려면 빌드 유형 DSL 참조를 읽어보세요.

제품 버전 구성

제품 버전을 생성하는 것은 빌드 유형을 생성하는 것과 비슷합니다. 즉, 제품 버전을 빌드 구성의 productFlavors 블록에 추가한 다음 원하는 설정을 포함하면 됩니다. 제품 버전은 defaultConfig와 동일한 속성을 지원합니다. 그 이유는 defaultConfig가 실제로 ProductFlavor 클래스에 속해 있기 때문입니다. 즉, defaultConfig 블록에 있는 모든 버전의 기본 구성을 제공할 수 있으며, 각 버전은 applicationId와 같은 모든 기본값을 변경할 수 있습니다. 애플리케이션 ID에 관한 자세한 내용은 애플리케이션 ID 설정을 참조하세요.

참고: main/ 매니페스트 파일에 있는 package 속성을 사용하여 패키지 이름을 지정해야 합니다. 또한 소스 코드에서 해당 패키지 이름을 사용하여 R 클래스를 참조하거나 상대적 활동 또는 서비스 등록을 확인해야 합니다. 이렇게 하면 소스 코드를 변경할 필요 없이 applicationId를 사용하여 각 제품 버전에 패키징 및 배포용 고유 ID를 제공할 수 있습니다.

모든 버전은 반드시 명명된 버전 차원에 속해 있어야 합니다. 차원은 제품 버전의 집합을 뜻합니다. 모든 버전은 반드시 버전 차원에 할당해야 하며 그렇게 하지 않으면 다음과 같은 빌드 오류가 발생합니다. 할당된 모듈이 하나의 버전 차원만 지정할 경우 Android Gradle 플러그인은 자동으로 그 모듈의 버전 모두를 해당 차원으로 할당합니다.

      Error:All flavors must now belong to a named flavor dimension.
      The flavor 'flavor_name' is not assigned to a flavor dimension.
    

다음 코드 샘플에서는 'version'으로 명명된 버전 차원을 생성하고 'demo'와 'full' 제품 버전을 추가합니다. 이러한 버전은 자체 applicationIdSuffix versionNameSuffix를 제공합니다.

    android {
        ...
        defaultConfig {...}
        buildTypes {
            debug{...}
            release{...}
        }
        // Specifies one flavor dimension.
        flavorDimensions "version"
        productFlavors {
            demo {
                // Assigns this product flavor to the "version" flavor dimension.
                // If you are using only one dimension, this property is optional,
                // and the plugin automatically assigns all the module's flavors to
                // that dimension.
                dimension "version"
                applicationIdSuffix ".demo"
                versionNameSuffix "-demo"
            }
            full {
                dimension "version"
                applicationIdSuffix ".full"
                versionNameSuffix "-full"
            }
        }
    }
    

참고: Google Play에서 다중 APK 지원을 사용하여 앱을 배포하려면 모든 변형에 동일한 applicationId 값을 할당하고 각 변형에 다른 versionCode를 부여하세요. 다양한 앱 변형을 별도의 앱으로 Google Play에 배포하려면, 각 변형에 다른 applicationId를 할당해야 합니다.

제품 버전을 생성하고 구성한 후, 알림바에서 지금 동기화를 클릭합니다. 동기화가 완료되면 Gradle은 빌드 유형과 제품 버전에 따라 자동으로 빌드 변형을 생성하고 <product-flavor><Build-Type>에 따라 빌드 변형의 이름을 지정합니다. 예를 들어, 'demo' 및 'full' 제품 버전을 생성하고 기본 'debug' 및 'release' 빌드 유형을 유지하면 Gradle은 다음과 같은 빌드 변형을 만듭니다.

  • demoDebug
  • demoRelease
  • fullDebug
  • fullRelease

빌드 변형은 자신이 빌드 및 실행하고자 하는 것으로 변경할 수 있습니다. 빌드 > 빌드 변형 선택으로 이동하여 드롭다운 메뉴에서 원하는 변형을 선택합니다. 그러나 고유한 기능과 리소스를 가진 빌드 변형의 사용자 지정을 시작하려면 소스 세트를 생성하고 관리하는 방법을 알아야 합니다.

버전 차원과 여러 제품 버전 결합

여러 제품 버전의 구성을 조합하려는 경우도 있을 것입니다. 예를 들어, API 레벨을 기준으로 'full' 및 'demo' 제품 버전에 서로 다른 구성을 생성할 수도 있습니다. 이 작업을 위해 Gradle용 Android 플러그인을 사용하면 여러 개의 제품 버전 그룹을 버전 차원으로 생성할 수 있습니다. 앱을 빌드할 때 Gradle은 빌드 유형 구성과 함께 최종 빌드 변형을 생성하기 위해 개발자가 정의하는 각 버전 차원에서 제품 버전 구성을 조합합니다. Gradle은 동일한 버전 차원에 속한 제품 버전을 조합하지 않습니다.

팁: ABI와 화면 밀도를 기반으로 다양한 버전의 앱을 만들려면 제품 버전을 사용하는 대신 여러 APK를 빌드해야 합니다.

다음 코드 샘플에서는 flavorDimensions 속성을 사용하여 'full' 및 'demo' 제품 버전을 그룹화하는 'mode' 버전 차원과 API 레벨을 기반으로 제품 버전 구성을 그룹화하는 'api' 버전 차원을 생성합니다.

    android {
      ...
      buildTypes {
        debug {...}
        release {...}
      }

      // Specifies the flavor dimensions you want to use. The order in which you
      // list each dimension determines its priority, from highest to lowest,
      // when Gradle merges variant sources and configurations. You must assign
      // each product flavor you configure to one of the flavor dimensions.
      flavorDimensions "api", "mode"

      productFlavors {
        demo {
          // Assigns this product flavor to the "mode" flavor dimension.
          dimension "mode"
          ...
        }

        full {
          dimension "mode"
          ...
        }

        // Configurations in the "api" product flavors override those in "mode"
        // flavors and the defaultConfig block. Gradle determines the priority
        // between flavor dimensions based on the order in which they appear next
        // to the flavorDimensions property above--the first dimension has a higher
        // priority than the second, and so on.
        minApi24 {
          dimension "api"
          minSdkVersion 24
          // To ensure the target device receives the version of the app with
          // the highest compatible API level, assign version codes in increasing
          // value with API level. To learn more about assigning version codes to
          // support app updates and uploading to Google Play, read Multiple APK Support
          versionCode 30000 + android.defaultConfig.versionCode
          versionNameSuffix "-minApi24"
          ...
        }

        minApi23 {
          dimension "api"
          minSdkVersion 23
          versionCode 20000  + android.defaultConfig.versionCode
          versionNameSuffix "-minApi23"
          ...
        }

        minApi21 {
          dimension "api"
          minSdkVersion 21
          versionCode 10000  + android.defaultConfig.versionCode
          versionNameSuffix "-minApi21"
          ...
        }
      }
    }
    ...
    

Gradle이 생성하는 빌드 변형의 개수는 각 버전 차원에 있는 버전의 수와 개발자가 구성하는 빌드 유형의 수를 곱한 값과 같습니다. Gradle이 각 빌드 변형 또는 해당 APK의 이름을 지정하면 우선순위가 높은 버전 차원에 속한 제품 버전이 먼저 나타난 다음에 우선순위가 낮은 차원의 제품 버전, 빌드 유형이 차례대로 나타납니다. Gradle은 위에서 예로 든 빌드 구성을 사용하여 다음과 같은 이름 지정 체계로 총 12개의 빌드 변형을 생성합니다.

빌드 변형: [minApi24, minApi23, minApi21][Demo, Full][Debug, Release]
해당 APK: app-[minApi24, minApi23, minApi21]-[demo, full]-[debug, release].apk
예:
빌드 변형: minApi24DemoDebug
해당 APK: app-minApi24-demo-debug.apk

각각의 개별 제품 버전 및 빌드 변형에 생성할 수 있는 소스 세트 디렉터리 외에, 제품 버전의 각 조합에 대한 소스 세트 디렉터리도 만들 수 있습니다. 예를 들어 자바 소스를 생성하여 src/demoMinApi24/java/ 디렉터리에 추가할 수 있고, Gradle은 이러한 두 제품 버전을 조합한 변형을 빌드할 때만 자바 소스를 사용합니다. 제품 버전 조합을 위해 생성하는 소스 세트의 우선순위가 각각의 개별 제품 버전에 속한 소스 세트보다 높습니다. 소스 세트와 Gradle이 리소스를 병합하는 방식에 관해 자세히 알아보려면 소스 세트 생성 방법에 관한 섹션을 읽어보세요.

변형 필터링

Gradle은 개발자가 구성하는 제품 버전과 빌드 유형의 가능한 모든 조합을 위한 빌드 변형을 생성합니다. 하지만 필요하지 않거나 프로젝트의 컨텍스트를 고려할 때 이치에 닿지 않는 특정 빌드 변형이 있을 수 있습니다. 모듈 레벨 build.gradle 파일에 변형 필터를 생성하여 특정 빌드 변형 구성을 삭제할 수 있습니다

이전 섹션에서 예시한 빌드 구성을 사용할 때 앱의 데모 버전에 API 레벨 23 이상만 지원할 계획이라고 가정해 보겠습니다. variantFilter 블록을 사용하여 'minApi21' 및 'demo' 제품 버전을 조합하는 빌드 변형 구성을 전부 필터링할 수 있습니다.

    android {
      ...
      buildTypes {...}

      flavorDimensions "api", "mode"
      productFlavors {
        demo {...}
        full {...}
        minApi24 {...}
        minApi23 {...}
        minApi21 {...}
      }

      variantFilter { variant ->
          def names = variant.flavors*.name
          // To check for a certain build type, use variant.buildType.name == "<buildType>"
          if (names.contains("minApi21") && names.contains("demo")) {
              // Gradle ignores any variants that satisfy the conditions above.
              setIgnore(true)
          }
      }
    }
    ...
    

빌드 구성에 변형 필터를 추가하고 알림바에서 Sync Now를 클릭하면 Gradle에서 개발자가 지정하는 조건을 충족하는 빌드 변형을 모두 무시하므로, 메뉴 바에서 Build > Select Build Variant을 클릭하거나 도구 창 모음에서 Build Variants 를 클릭하면 이러한 빌드 변형이 더 이상 드롭다운 메뉴에 나타나지 않습니다.

소스 세트 생성

기본적으로 Android 스튜디오는 모든 빌드 변형 간에 공유하려는 모든 것에 main/ 소스 세트 및 디렉터리를 생성합니다. 그러나 특정 빌드 유형, 제품 버전(그리고 버전 차원을 사용하는 경우 제품 버전의 조합) 및 빌드 변형에 Gradle이 컴파일하고 패키징하는 파일을 정확히 제어하기 위해 새로운 소스 세트를 생성할 수 있습니다. 예를 들어, 기본적인 기능은 main/ 소스 세트에 정의하고, 제품 버전 소스 세트를 사용하여 다양한 클라이언트의 앱 브랜드를 변경하거나 디버그 빌드 유형을 사용하는 빌드 변형에 대해서만 특별 권한과 로깅 기능을 포함할 수 있습니다.

Gradle은 개발자가 main/ 소스 세트와 유사한 방식으로 소스 세트 파일과 디렉터리를 구성할 것으로 예상합니다. 예를 들어 Gradle은 'debug' 빌드 유형 전용의 자바 클래스 파일이 src/debug/java/ 디렉터리에 있을 것으로 예상합니다.

Gradle용 Android 플러그인은 각 빌드 유형, 제품 버전 및 빌드 변형에 관한 파일 구성 방법을 보여주는 유용한 Gradle 작업을 제공합니다. 예를 들어, 다음 작업 출력 샘플은 Gradle이 'debug' 빌드 유형에 대해 특정 파일을 찾을 것으로 예상되는 위치를 설명합니다.

    ------------------------------------------------------------
    Project :app
    ------------------------------------------------------------

    ...

    debug
    ----
    Compile configuration: compile
    build.gradle name: android.sourceSets.debug
    Java sources: [app/src/debug/java]
    Manifest file: app/src/debug/AndroidManifest.xml
    Android resources: [app/src/debug/res]
    Assets: [app/src/debug/assets]
    AIDL sources: [app/src/debug/aidl]
    RenderScript sources: [app/src/debug/rs]
    JNI sources: [app/src/debug/jni]
    JNI libraries: [app/src/debug/jniLibs]
    Java-style resources: [app/src/debug/resources]
    

이 출력을 보려면 다음과 같이 진행합니다.

  1. IDE 창 오른쪽에서 Gradle 을 클릭합니다.
  2. MyApplication > Tasks > android로 이동하여 sourceSets를 두 번 클릭합니다. Gradle에서 작업을 실행하면 Run 창이 열리고 출력 내용이 표시됩니다.
  3. 표시된 내용이 위와 같은 텍스트 모드가 아닌 경우 Run 창의 왼쪽에 있는 Toggle view 를 클릭합니다.

참고: 이 작업 출력은 앱에 테스트를 실행하는 데 사용할 파일의 소스 세트(예: test/androidTest/ 테스트 소스 세트)를 구성하는 방법도 보여줍니다.

새 빌드 변형을 생성할 때 Android 스튜디오가 소스 세트 디렉터리를 자동으로 생성하지는 않지만, 도움이 되는 몇 가지 옵션을 제공합니다. 예를 들어 'debug' 빌드 유형에 java/ 디렉터리만 만들려면 다음과 같이 하면 됩니다.

  1. Project(프로젝트) 창을 열고 창 상단의 드롭다운 메뉴에서 Project(프로젝트) 뷰를 선택합니다.
  2. MyProject/app/src/로 이동합니다.
  3. src 디렉터리를 마우스 오른쪽 버튼으로 클릭하고 New > Folder > 자바 Folder를 선택합니다.
  4. Target Source Set(타겟 소스 세트) 옆의 드롭다운 메뉴에서 debug(디버그)를 선택합니다.
  5. Finish(마침)를 클릭합니다.

Android 스튜디오에서는 디버그 빌드 유형에 소스 세트 디렉터리를 생성한 다음, 그 안에 java/ 디렉터리를 생성합니다. 또는 특정 빌드 변형을 위한 프로젝트에 새 파일을 추가할 때 Android 스튜디오가 자동으로 디렉터리를 생성하도록 설정할 수 있습니다. 예를 들어 'debug' 빌드 유형에 Values XML 파일을 생성하려면 다음을 따르세요.

  1. Project 창에서 src 디렉터리를 마우스 오른쪽 버튼으로 클릭하고 New > XML > Values XML File을 선택합니다.
  2. XML 파일의 이름을 입력하거나 기본 이름을 유지합니다.
  3. Target Source Set(타겟 소스 세트) 옆의 드롭다운 메뉴에서 debug(디버그)를 선택합니다.
  4. Finish(마침)를 클릭합니다.

'debug' 빌드 유형이 타겟 소스 세트로 지정되었기 때문에 Android 스튜디오는 XML 파일을 생성할 때 필요한 디렉터리를 자동으로 생성합니다. 결과 디렉터리 구조는 그림 2와 같아야 합니다.

그림 2. 디버그 빌드 유형의 새로운 소스 세트 디렉터리

또한 동일한 절차를 사용하여 제품 버전(예: src/demo/)과 빌드 변형(예: src/demoDebug/)에 대한 소스 세트 디렉터리를 생성할 수도 있습니다. 또는 특정 빌드 변형(예: src/androidTestDemoDebug/)을 대상으로 하는 테스트 소스 세트를 생성할 수 있습니다. 자세히 알아보려면 테스트 소스 세트로 이동하세요.

기본 소스 세트 구성 변경

Gradle이 예상하는 기본 소스 세트 파일 구조로 구성되지 않은 소스가 있는 경우에는 앞서 소스 세트 생성 섹션에서 설명한 것처럼 sourceSets 블록을 사용하여 Gradle이 소스 세트의 각 구성요소에 대해 파일을 수집하는 위치를 변경할 수 있습니다. 파일의 위치를 변경할 필요는 없습니다. Gradle이 각 소스 세트 구성요소의 파일을 당연히 찾을 수 있을 것으로 예상하는 모듈 레벨 build.gradle 파일에 상대적인 경로를 Gradle에 제공하기만 하면 됩니다. 어떤 구성요소를 구성할 수 있을지, 그리고 이러한 구성요소를 여러 파일이나 디렉터리로 매핑할 수 있을지 알아보려면 Gradle DSL 참조용 Android 플러그인을 읽어보세요.

다음은 app/other/ 디렉터리의 소스를 main 소스 세트의 특정 구성요소로 매핑하고 androidTest 소스 세트의 루트 디렉터리를 변경하는 코드 샘플입니다.

    android {
      ...
      sourceSets {
        // Encapsulates configurations for the main source set.
        main {
          // Changes the directory for Java sources. The default directory is
          // 'src/main/java'.
          java.srcDirs = ['other/java']

          // If you list multiple directories, Gradle uses all of them to collect
          // sources. Because Gradle gives these directories equal priority, if
          // you define the same resource in more than one directory, you get an
          // error when merging resources. The default directory is 'src/main/res'.
          res.srcDirs = ['other/res1', 'other/res2']

          // Note: You should avoid specifying a directory which is a parent to one
          // or more other directories you specify. For example, avoid the following:
          // res.srcDirs = ['other/res1', 'other/res1/layouts', 'other/res1/strings']
          // You should specify either only the root 'other/res1' directory, or only the
          // nested 'other/res1/layouts' and 'other/res1/strings' directories.

          // For each source set, you can specify only one Android manifest.
          // By default, Android Studio creates a manifest for your main source
          // set in the src/main/ directory.
          manifest.srcFile 'other/AndroidManifest.xml'
          ...
        }

        // Create additional blocks to configure other source sets.
        androidTest {

          // If all the files for a source set are located under a single root
          // directory, you can specify that directory using the setRoot property.
          // When gathering sources for the source set, Gradle looks only in locations
          // relative to the root directory you specify. For example, after applying the
          // configuration below for the androidTest source set, Gradle looks for Java
          // sources only in the src/tests/java/ directory.
          setRoot 'src/tests'
          ...
        }
      }
    }
    ...
    

소스 세트로 빌드

소스 세트 디렉터리를 사용하여 특정 구성으로만 패키징하려는 코드와 리소스를 포함할 수 있습니다. 예를 들어, 'demo' 제품 버전과 'debug' 빌드 유형의 교차 제품(crossproduct)인 'demoDebug' 빌드 변형을 빌드하는 경우, Gradle은 아래의 디렉터리를 찾아서 다음과 같이 우선순위를 부여합니다.

  1. src/demoDebug/(빌드 변형 소스 세트)
  2. src/debug/(빌드 유형 소스 세트)
  3. src/demo/(제품 버전 소스 세트)
  4. src/main/(메인 소스 세트)

참고: 여러 제품 버전을 조합할 경우 제품 버전 간의 우선순위는 제품 버전이 속한 버전 차원에 따라 결정됩니다. android.flavorDimensions 속성을 가진 버전 차원을 나열할 때 맨 처음에 나열하는 버전 차원에 속한 제품 버전이 두 번째 버전 차원에 속한 제품 버전보다 우선순위가 높고 그 이후로도 마찬가지 방식으로 적용됩니다. 또한, 제품 버전의 조합을 위해 생성하는 소스 세트의 우선순위가 각각의 개별 제품 버전에 속한 소스 세트보다 높습니다.

위에 나열된 순서는 Gradle이 코드와 리소스를 조합할 때 어떤 소스 세트의 우선순위가 더 높은지 판별합니다. demoDebug/ 소스 세트 디렉터리에는 해당 빌드 변형에 특정한 파일이 포함될 가능성이 높으므로, debug/에 정의된 파일이 demoDebug/에도 포함된 경우 Gradle은 demoDebug/ 소스 세트에 있는 파일을 사용합니다. 마찬가지로, Gradle은 main/에 있는 파일보다 빌드 유형 및 제품 버전 소스 세트에 있는 동일한 파일에 더 높은 우선순위를 부여합니다. Gradle은 다음과 같은 빌드 규칙을 적용할 때 이 우선순위를 고려합니다.

  • java/ 디렉터리에 있는 모든 소스 코드가 함께 컴파일되어 단일 출력을 생성합니다.

    참고: 둘 이상의 소스 세트 디렉터리에 동일한 자바 클래스가 정의된 경우, 주어진 빌드 변형에 빌드 오류가 발생합니다. 예를 들어 디버그 APK를 빌드할 때는 src/debug/Utility.javasrc/main/Utility.java를 모두 정의할 수 없습니다. 그 이유는 Gradle이 빌드 프로세스 중에 이 두 디렉터리를 검색하고 '중복 클래스' 오류를 일으키기 때문입니다. 다른 빌드 유형에 다른 버전의 Utility.java를 원하는 경우에는 각 빌드 유형이 자체 파일 버전을 정의하고 main/ 소스 세트에 포함하지 않도록 할 수 있습니다.

  • 매니페스트는 단일 매니페스트로 병합됩니다. 우선순위는 위 목록과 같은 순서로 지정됩니다. 즉, 빌드 유형의 매니페스트 설정은 제품 버전의 매니페스트 설정보다 우선합니다. 자세히 알아보려면 매니페스트 병합을 참조하세요.
  • 마찬가지로, values/ 디렉터리의 파일도 함께 병합됩니다. 두 파일이 동일한 이름을 공유하는 경우(예: 두 개의 strings.xml 파일) 우선순위는 위 목록과 같은 순서로 지정됩니다. 즉, 빌드 유형 소스 세트의 파일에 정의된 값은 제품 버전의 동일한 파일에 정의된 값보다 우선합니다.
  • res/asset/ 디렉터리에 있는 리소스가 함께 패키징됩니다. 동일한 이름의 리소스가 둘 이상의 소스 세트에 정의된 경우 우선순위는 위 목록과 같은 순서로 지정됩니다.
  • 마지막으로, APK를 빌드할 때 Gradle은 라이브러리 모듈 종속성에 포함된 리소스와 매니페스트에는 가장 낮은 우선순위를 부여합니다.

종속성 선언

다음 샘플에 나오는 것처럼, 빌드 변형 또는 테스트 소스 세트의 이름을 Implementation 키워드 앞에 붙여 특정 빌드 변형 또는 테스트 소스 세트의 종속성을 구성할 수 있습니다.

    dependencies {
        // Adds the local "mylibrary" module as a dependency to the "free" flavor.
        freeImplementation project(":mylibrary")

        // Adds a remote binary dependency only for local tests.
        testImplementation 'junit:junit:4.12'

        // Adds a remote binary dependency only for the instrumented test APK.
        androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.2'
    }
    

자세한 내용은 빌드 종속성 추가를 참조하세요.

서명 설정 구성

릴리스 빌드의 서명 구성을 명시적으로 구성하지 않는 경우, Gradle은 이 빌드의 APK에 서명하지 않습니다. Android 스튜디오를 사용하여 쉽게 릴리스 키를 만들고 릴리스 빌드 유형에 서명할 수 있습니다.

Gradle 빌드 구성을 사용하여 릴리스 빌드 유형의 서명 구성을 수동으로 구성하려면 다음을 따르세요.

  1. 키 저장소를 생성합니다. 키 저장소는 비공개 키 세트가 포함된 바이너리 파일입니다. 키 저장소는 안전하고 보안이 유지되는 장소에 보관해야 합니다.
  2. 비공개 키를 생성합니다. 비공개 키는 개인이나 회사와 같이 앱으로 식별되는 엔티티를 나타냅니다.
  3. 서명 구성을 모듈 레벨 build.gradle 파일에 추가합니다.

        ...
        android {
            ...
            defaultConfig {...}
            signingConfigs {
                release {
                    storeFile file("myreleasekey.keystore")
                    storePassword "password"
                    keyAlias "MyReleaseKey"
                    keyPassword "password"
                }
            }
            buildTypes {
                release {
                    ...
                    signingConfig signingConfigs.release
                }
            }
        }
        

서명된 APK를 생성하려면, 메뉴 바에서 Build(빌드) > Generate Signed APK(서명된 APK 생성)를 선택합니다. 이제 app/build/apk/app-release.apk의 패키지가 릴리스 키로 서명됩니다.

참고: 릴리스 키와 키 저장소의 비밀번호를 빌드 파일에 포함하는 것은 보안에 좋지 않습니다. 대신 환경 변수에서 이러한 비밀번호를 가져오도록 빌드 파일을 구성하거나 빌드 프로세스에서 이러한 비밀번호를 입력하도록 메시지를 표시할 수 있습니다.

환경 변수에서 이러한 비밀번호를 가져오려면 다음과 같이 하세요.

    storePassword System.getenv("KSTOREPWD")
    keyPassword System.getenv("KEYPWD")
    

명령줄에서 빌드를 호출하는 경우, 빌드 프로세스에서 이러한 비밀번호를 입력하도록 메시지를 표시하려면 다음과 같이 하세요.

    storePassword System.console().readLine("\nKeystore password: ")
    keyPassword System.console().readLine("\nKey password: ")
    

이 프로세스를 완료한 후 앱을 배포하고 Google Play에 게시할 수 있습니다.

경고: 키 저장소와 비공개 키는 안전한 장소에 보관해야 하며, 안전한 백업을 갖고 있어야 합니다. Google Play에 앱을 게시하고 앱에 서명한 비공개 키를 분실하면 앱에 업데이트를 전혀 게시할 수 없게 됩니다. 항상 모든 앱 버전에서 같은 키로 서명해야 하기 때문입니다.

Wear OS 앱 서명

Wear OS 앱을 게시할 때 시계 APK와 선택적 전화 APK에 서명해야 합니다. Wear OS 앱을 패키징하고 이 APK에 서명하는 방법에 관한 자세한 내용은 웨어러블 앱 패키징을 참조하세요.