কম্পোজ কম্পাইলার গ্রেডল প্লাগইন সেট আপ করুন

গ্রেডল ব্যবহারকারীদের জন্য, আপনি কম্পোজ সেট আপ এবং কনফিগার করা সহজ করতে কম্পোজ কম্পাইলার গ্রেডল প্লাগইন ব্যবহার করতে পারেন।

দ্রষ্টব্য: কম্পোজ কম্পাইলার গ্রেডল প্লাগইন শুধুমাত্র কোটলিন ২.০+ থেকে পাওয়া যায়। মাইগ্রেশন নির্দেশাবলীর জন্য, "জেটপ্যাক কম্পোজ কম্পাইলার কোটলিন রিপোজিটরিতে স্থানান্তরিত হচ্ছে" দেখুন। মাইগ্রেশনের উদাহরণের জন্য, কম্পোজ নমুনাগুলিতে কম্পোজ নমুনা পিআর দেখুন।

গ্রেডল সংস্করণ ক্যাটালগ দিয়ে সেট আপ করুন

নিম্নলিখিত নির্দেশাবলীতে আপনি কীভাবে কম্পোজ কম্পাইলার গ্রেডল প্লাগইন সেট আপ করতে পারেন তা বর্ণনা করা হয়েছে:

1. আপনার libs.versions.toml ফাইল থেকে, Compose Compiler এর যেকোনো রেফারেন্স মুছে ফেলুন।
2. প্লাগইন বিভাগে, নিম্নলিখিত নতুন নির্ভরতা যোগ করুন।

[versions]
kotlin = "2.0.0"

[plugins]
org-jetbrains-kotlin-android = { id = "org.jetbrains.kotlin.android", version.ref = "kotlin" }

// Add this line
compose-compiler = { id = "org.jetbrains.kotlin.plugin.compose", version.ref = "kotlin" }

1. আপনার প্রোজেক্টের রুট build.gradle.kts ফাইলে, প্লাগইন বিভাগে নিম্নলিখিত স্নিপেটটি যোগ করুন।

plugins {
   // Existing plugins
   alias(libs.plugins.compose.compiler) apply false
}

1. কম্পোজ ব্যবহার করে এমন প্রতিটি মডিউলে, প্লাগইনটি নিম্নরূপ প্রয়োগ করুন।

plugins {
   // Existing plugins
   alias(libs.plugins.compose.compiler)
}

যদি আপনি ডিফল্ট সেটআপ ব্যবহার করেন, তাহলে আপনার অ্যাপটি এখন তৈরি এবং কম্পাইল করা উচিত। যদি আপনি কম্পোজ কম্পাইলারে কাস্টম বিকল্পগুলি কনফিগার করে থাকেন, তাহলে নিম্নলিখিত বিভাগটি দেখুন।

Set up the Compose Compiler without Gradle version catalogs

আপনার কম্পোজ ব্যবহার করা মডিউলের সাথে সম্পর্কিত build.gradle.kts ফাইলগুলিতে নিম্নলিখিত প্লাগইনটি যুক্ত করুন:

plugins {
    id("org.jetbrains.kotlin.plugin.compose") version "2.0.0" // this version matches your Kotlin version
}

আপনার শীর্ষ-স্তরের প্রকল্প build.gradle.kts ফাইলে এই ক্লাসপাথটি যুক্ত করার প্রয়োজন হতে পারে:

buildscript {
    dependencies {
        classpath("org.jetbrains.kotlin.plugin.compose:org.jetbrains.kotlin.plugin.compose.gradle.plugin:2.0.0")
    }
}

কম্পোজ কম্পাইলার গ্রেডল প্লাগইন সহ কনফিগারেশন বিকল্পগুলি

Gradle প্লাগইন ব্যবহার করে Compose কম্পাইলার কনফিগার করতে, উপরের স্তরে মডিউলের build.gradle.kts ফাইলে composeCompiler ব্লক যোগ করুন।

android { … }

composeCompiler {
    reportsDestination = layout.buildDirectory.dir("compose_compiler")
    stabilityConfigurationFile = rootProject.layout.projectDirectory.file("stability_config.conf")
}

উপলব্ধ বিকল্পগুলির সম্পূর্ণ তালিকার জন্য, ডকুমেন্টেশন দেখুন।

কম্পোজ নির্ভরতা সেট আপ করুন

আপনার অ্যাপের build.gradle ফাইলে নিম্নলিখিত সংজ্ঞাটি যোগ করুন:

খাঁজকাটা

android {
    buildFeatures {
        compose true
    }
}

কোটলিন

android {
    buildFeatures {
        compose = true
    }
}

Android BuildFeatures ব্লকের ভিতরে compose ফ্ল্যাগটিকে true তে সেট করলে Android Studio-তে Compose কার্যকারিতা সক্ষম হয়।

অবশেষে, নিম্নলিখিত ব্লক থেকে আপনার নির্ভরতায় Compose BOM এবং আপনার প্রয়োজনীয় Compose লাইব্রেরি নির্ভরতার উপসেট যোগ করুন:

খাঁজকাটা

dependencies {

    def composeBom = platform('androidx.compose:compose-bom:2026.01.01')
    implementation composeBom
    androidTestImplementation composeBom

    // Choose one of the following:
    // Material Design 3
    implementation 'androidx.compose.material3:material3'
    // or skip Material Design and build directly on top of foundational components
    implementation 'androidx.compose.foundation:foundation'
    // or only import the main APIs for the underlying toolkit systems,
    // such as input and measurement/layout
    implementation 'androidx.compose.ui:ui'

    // Android Studio Preview support
    implementation 'androidx.compose.ui:ui-tooling-preview'
    debugImplementation 'androidx.compose.ui:ui-tooling'

    // UI Tests
    androidTestImplementation 'androidx.compose.ui:ui-test-junit4'
    debugImplementation 'androidx.compose.ui:ui-test-manifest'

    // Optional - Add window size utils
    implementation 'androidx.compose.material3.adaptive:adaptive'

    // Optional - Integration with activities
    implementation 'androidx.activity:activity-compose:1.11.0'
    // Optional - Integration with ViewModels
    implementation 'androidx.lifecycle:lifecycle-viewmodel-compose:2.8.5'
    // Optional - Integration with LiveData
    implementation 'androidx.compose.runtime:runtime-livedata'
    // Optional - Integration with RxJava
    implementation 'androidx.compose.runtime:runtime-rxjava2'

}

কোটলিন

dependencies {

    val composeBom = platform("androidx.compose:compose-bom:2026.01.01")
    implementation(composeBom)
    androidTestImplementation(composeBom)

    // Choose one of the following:
    // Material Design 3
    implementation("androidx.compose.material3:material3")
    // or skip Material Design and build directly on top of foundational components
    implementation("androidx.compose.foundation:foundation")
    // or only import the main APIs for the underlying toolkit systems,
    // such as input and measurement/layout
    implementation("androidx.compose.ui:ui")

    // Android Studio Preview support
    implementation("androidx.compose.ui:ui-tooling-preview")
    debugImplementation("androidx.compose.ui:ui-tooling")

    // UI Tests
    androidTestImplementation("androidx.compose.ui:ui-test-junit4")
    debugImplementation("androidx.compose.ui:ui-test-manifest")

    // Optional - Add window size utils
    implementation("androidx.compose.material3.adaptive:adaptive")

    // Optional - Integration with activities
    implementation("androidx.activity:activity-compose:1.11.0")
    // Optional - Integration with ViewModels
    implementation("androidx.lifecycle:lifecycle-viewmodel-compose:2.8.5")
    // Optional - Integration with LiveData
    implementation("androidx.compose.runtime:runtime-livedata")
    // Optional - Integration with RxJava
    implementation("androidx.compose.runtime:runtime-rxjava2")

}

দ্রষ্টব্য: সমস্ত লাইব্রেরি গ্রুপের সংস্করণগুলিকে সিঙ্কে রাখার জন্য, জেটপ্যাক কম্পোজ একটি বিল অফ ম্যাটেরিয়ালস (BOM) ব্যবহার করে পাঠানো হয়। বিল অফ ম্যাটেরিয়ালস পৃষ্ঠায় এটি সম্পর্কে আরও পড়ুন।